Jak automatycznie instalować pakiety Emacsa poprzez podanie listy nazw pakietów?

; list the packages you want
(setq package-list '(package1 package2))

; list the repositories containing them
(setq package-archives '(("elpa" . "http://tromey.com/elpa/")
                         ("gnu" . "http://elpa.gnu.org/packages/")
                         ("marmalade" . "http://marmalade-repo.org/packages/")))

; activate all the packages (in particular autoloads)
(package-initialize)

; fetch the list of packages available 
(unless package-archive-contents
  (package-refresh-contents))

; install the missing packages
(dolist (package package-list)
  (unless (package-installed-p package)
    (package-install package)))

Emacs 25.1+ automatycznie śledzi pakiety zainstalowane przez użytkownika w zmiennej package-selected-packages. package-install zaktualizuje zmienną customize, a wszystkie wybrane pakiety można zainstalować za pomocą funkcji package-install-selected-packages.

Kolejną wygodną zaletą tego podejścia jest to, że można użyć package-autoremove do automatycznego usuwania pakietów, które nie są zawarte w package-selected-packages (chociaż zachowa to zależności).

(package-initialize)
(unless package-archive-contents
  (package-refresh-contents))
(package-install-selected-packages)

Źródło: http://endlessparentheses.com/new-in-package-el-in-emacs-25-1-user-selected-packages.html

Oto kod, którego używam do Emacs Prelude:

(require 'package)
(require 'melpa)
(add-to-list 'package-archives
             '("melpa" . "http://melpa.milkbox.net/packages/") t)
(package-initialize)

(setq url-http-attempt-keepalives nil)

(defvar prelude-packages
  '(ack-and-a-half auctex clojure-mode coffee-mode deft expand-region
                   gist haml-mode haskell-mode helm helm-projectile inf-ruby
                   magit magithub markdown-mode paredit projectile
                   python sass-mode rainbow-mode scss-mode solarized-theme
                   volatile-highlights yaml-mode yari yasnippet zenburn-theme)
  "A list of packages to ensure are installed at launch.")

(defun prelude-packages-installed-p ()
  (loop for p in prelude-packages
        when (not (package-installed-p p)) do (return nil)
        finally (return t)))

(unless (prelude-packages-installed-p)
  ;; check for new packages (package versions)
  (message "%s" "Emacs Prelude is now refreshing its package database...")
  (package-refresh-contents)
  (message "%s" " done.")
  ;; install the missing packages
  (dolist (p prelude-packages)
    (when (not (package-installed-p p))
      (package-install p))))

(provide 'prelude-packages)

Jeśli nie używasz MELPA nie musisz go wymagać (a jeśli nie melpa.el musi być na load-path (lub zainstalowany przez MELPA). Pakiet db nie jest odświeżany za każdym razem ( ponieważ znacznie spowolniłoby to uruchamianie) - tylko wtedy, gdy obecne są odinstalowane Pakiety.

Nikt jeszcze nie wspomniał beczka , ale nadaje się do tego zadania.

Zasadniczo tworzysz ~/.emacs.d/Cask listę pakietów, które chcesz zainstalować. Na przykład:

(source melpa)
(depends-on "expand-region")
(depends-on "goto-last-change")
; ... etc

Uruchomienie cask z wiersza poleceń spowoduje zainstalowanie tych pakietów za Ciebie i wszelkich zależności, których potrzebują.

Możesz również automatycznie aktualizować zainstalowane pakiety za pomocą cask update.

Wywołanie package-install z nazwą pakietu jako symbolem. Nazwy pakietów można znaleźć, wywołując package-install interaktywnie i uzupełniając nazwę. Funkcja package-installed-p poinformuje cię, czy została już zainstalowana.

Na przykład:

(mapc
 (lambda (package)
   (or (package-installed-p package)
       (package-install package)))
 '(package1 package2 package3))

Lubię sprawdzać, czy użytkownik chce najpierw zainstalować pakiety, jak to zrobiono w Ta odpowiedź . Również odświeżam Zawartość pakietu raz przed zainstalowaniem czegokolwiek. Nie jestem pewien, czy to najlepszy sposób, ale nie sądzę, że najlepsze odpowiedzi robiły to za mnie.

(setq required-pkgs '(jedi flycheck cider clojure-mode paredit markdown-mode jsx-mode company))

(require 'cl)

(setq pkgs-to-install
      (let ((uninstalled-pkgs (remove-if 'package-installed-p required-pkgs)))
        (remove-if-not '(lambda (pkg) (y-or-n-p (format "Package %s is missing. Install it? " pkg))) uninstalled-pkgs)))

(when (> (length pkgs-to-install) 0)
  (package-refresh-contents)
  (dolist (pkg pkgs-to-install)
    (package-install pkg)))

(require 'cl)
(require 'package)

(setq cfg-var:packages '(
       emmet-mode
       ergoemacs-mode
       flycheck
       flycheck-pyflakes
       monokai-theme
       py-autopep8
       py-isort
       rainbow-mode
       yafolding
       yasnippet))

(defun cfg:install-packages ()
    (let ((pkgs (remove-if #'package-installed-p cfg-var:packages)))
        (when pkgs
            (message "%s" "Emacs refresh packages database...")
            (package-refresh-contents)
            (message "%s" " done.")
            (dolist (p cfg-var:packages)
                (package-install p)))))

(add-to-list 'package-archives '("gnu" . "http://elpa.gnu.org/packages/") t)
(add-to-list 'package-archives '("melpa" . "http://melpa.org/packages/") t)
(add-to-list 'package-archives '("melpa-stable" . "http://stable.melpa.org/packages/") t)
(add-to-list 'package-archives '("org" . "http://orgmode.org/elpa/") t)
(package-initialize)

(cfg:install-packages)

Oto moje, jest krótsze:)

(mapc
 (lambda (package)
   (unless (package-installed-p package)
     (progn (message "installing %s" package)
            (package-refresh-contents)
            (package-install package))))
 '(browse-kill-ring flycheck less-css-mode tabbar org auto-complete undo-tree clojure-mode markdown-mode yasnippet paredit paredit-menu php-mode haml-mode rainbow-mode fontawesome))

Napotkałem problem, że nic się nie stało po dodaniu (package-install 'org) do .emacs. Chciałem zainstalować aktualną wersję org-mode i wbudowany org-mode jest dość stary.

Wykopałem kod źródłowy package-install z Emacsa 25.3.1. Funkcja self sprawdza już, czy pakiet jest zainstalowany, czy nie i odmawia zainstalowania go, jeśli pakiet jest już zainstalowany. Więc czek (unless (package-installed-p package) ...) z odpowiedzi 10093312 jest w rzeczywistości nie na miejscu.

(defun package-install (pkg &optional dont-select)
  "Install the package PKG.
PKG can be a package-desc or a symbol naming one of the available packages
in an archive in `package-archives'.  Interactively, prompt for its name.

If called interactively or if DONT-SELECT nil, add PKG to
`package-selected-packages'.

If PKG is a package-desc and it is already installed, don't try
to install it but still mark it as selected."
  (interactive
   (progn
     ;; Initialize the package system to get the list of package
     ;; symbols for completion.
     (unless package--initialized
       (package-initialize t))
     (unless package-archive-contents
       (package-refresh-contents))
     (list (intern (completing-read
                    "Install package: "
                    (delq nil
                          (mapcar (lambda (elt)
                                    (unless (package-installed-p (car elt))
                                      (symbol-name (car elt))))
                                  package-archive-contents))
                    nil t))
           nil)))
  (add-hook 'post-command-hook #'package-menu--post-refresh)
  (let ((name (if (package-desc-p pkg)
                  (package-desc-name pkg)
                pkg)))
    (unless (or dont-select (package--user-selected-p name))
      (package--save-selected-packages
       (cons name package-selected-packages)))
    (if-let ((transaction
              (if (package-desc-p pkg)
                  (unless (package-installed-p pkg)
                    (package-compute-transaction (list pkg)
                                                 (package-desc-reqs pkg)))
                (package-compute-transaction () (list (list pkg))))))
        (package-download-transaction transaction)
      (message "`%s' is already installed" name))))

Wbudowany org-mode również się liczy jako zainstalowany i package-install odmawia zainstalowania nowszej wersji z ELPA. Po spędzeniu trochę czasu na czytaniu pakietu.el, wymyśliłem następujące rozwiązanie.

(dolist (package (package-compute-transaction
                  () (list (list 'python '(0 25 1))
                           (list 'org '(20171211)))))
  ;; package-download-transaction may be more suitable here and
  ;; I don't have time to check it
  (package-install package))

Powodem, dla którego to działa jest to, że funkcje rodziny package-* obsługują argumenty w różny sposób w zależności od tego, czy jest to symbol, czy obiekt package-desc. Informacje o wersji dla package-install można podać tylko za pomocą obiektu package-desc.