Określanie, czy obiekt jest członkiem kolekcji w VBA

Czy to nie wystarczy?

Public Function Contains(col As Collection, key As Variant) As Boolean
Dim obj As Variant
On Error GoTo err
    Contains = True
    obj = col(key)
    Exit Function
err:

    Contains = False
End Function

Nie do końca eleganckie, ale najlepszym (i najszybszym) rozwiązaniem, jakie mogłem znaleźć, było użycie OnError. Będzie to znacznie szybsze niż iteracja dla każdej średniej i dużej kolekcji.

Public Function InCollection(col As Collection, key As String) As Boolean
  Dim var As Variant
  Dim errNumber As Long

  InCollection = False
  Set var = Nothing

  Err.Clear
  On Error Resume Next
    var = col.Item(key)
    errNumber = CLng(Err.Number)
  On Error GoTo 0

  '5 is not in, 0 and 438 represent incollection
  If errNumber = 5 Then ' it is 5 if not in collection
    InCollection = False
  Else
    InCollection = True
  End If

End Function

To stare pytanie. Dokładnie przejrzałem wszystkie odpowiedzi i komentarze, przetestowałem rozwiązania pod kątem wydajności.

Wymyśliłem najszybszą opcję dla mojego środowiska, która nie zawodzi, gdy Kolekcja zawiera zarówno obiekty, jak i prymitywy.

Public Function ExistsInCollection(col As Collection, key As Variant) As Boolean
    On Error GoTo err
    ExistsInCollection = True
    IsObject(col.item(key))
    Exit Function
err:
    ExistsInCollection = False
End Function

Ponadto rozwiązanie to nie zależy od zakodowanych wartości błędów. Tak więc parametr col As Collection może zostać zastąpiony przez inną zmienną typu collection, a funkcja musi nadal działać. Np. o moim obecnym projekcie, Będę miał to jako col As ListColumns.

Stworzyłem To rozwiązanie z powyższych sugestii zmieszanych z rozwiązaniem mikrosoftów do iteracji poprzez zbiór.

Public Function InCollection(col As Collection, Optional vItem, Optional vKey) As Boolean
On Error Resume Next

Dim vColItem As Variant

InCollection = False

If Not IsMissing(vKey) Then
    col.item vKey

    '5 if not in collection, it is 91 if no collection exists
    If Err.Number <> 5 And Err.Number <> 91 Then
        InCollection = True
    End If
ElseIf Not IsMissing(vItem) Then
    For Each vColItem In col
        If vColItem = vItem Then
            InCollection = True
            GoTo Exit_Proc
        End If
    Next vColItem
End If

Exit_Proc:
Exit Function
Err_Handle:
Resume Exit_Proc
End Function

Możesz skrócić sugerowany kod do tego celu, a także uogólnić na nieoczekiwane błędy. Proszę bardzo:

Public Function InCollection(col As Collection, key As String) As Boolean

  On Error GoTo incol
  col.Item key

incol:
  InCollection = (Err.Number = 0)

End Function

W twoim konkretnym przypadku (TableDefs) iteracja nad kolekcją i sprawdzanie nazwy jest dobrym podejściem. Jest to w porządku, ponieważ klucz dla kolekcji (Name) jest właściwością klasy w kolekcji.

Ale w ogólnym przypadku kolekcji VBA, klucz niekoniecznie będzie częścią obiektu w kolekcji (np. możesz używać kolekcji jako słownika, z kluczem, który nie ma nic wspólnego z obiektem w kolekcji). W tym przypadku nie masz wyboru ale aby spróbować uzyskać dostęp do elementu i złapać błąd.

Mam jakiś edit, najlepiej pracuje dla kolekcji:

Public Function Contains(col As collection, key As Variant) As Boolean
    Dim obj As Object
    On Error GoTo err
    Contains = True
    Set obj = col.Item(key)
    Exit Function
    
err:
    Contains = False
End Function

Ta wersja działa dla typów prymitywnych i klas (w tym krótka metoda testowa)

' TODO: change this to the name of your module
Private Const sMODULE As String = "MVbaUtils"

Public Function ExistsInCollection(oCollection As Collection, sKey As String) As Boolean
    Const scSOURCE As String = "ExistsInCollection"

    Dim lErrNumber As Long
    Dim sErrDescription As String

    lErrNumber = 0
    sErrDescription = "unknown error occurred"
    Err.Clear
    On Error Resume Next
        ' note: just access the item - no need to assign it to a dummy value
        ' and this would not be so easy, because we would need different
        ' code depending on the type of object
        ' e.g.
        '   Dim vItem as Variant
        '   If VarType(oCollection.Item(sKey)) = vbObject Then
        '       Set vItem = oCollection.Item(sKey)
        '   Else
        '       vItem = oCollection.Item(sKey)
        '   End If
        oCollection.Item sKey
        lErrNumber = CLng(Err.Number)
        sErrDescription = Err.Description
    On Error GoTo 0

    If lErrNumber = 5 Then ' 5 = not in collection
        ExistsInCollection = False
    ElseIf (lErrNumber = 0) Then
        ExistsInCollection = True
    Else
        ' Re-raise error
        Err.Raise lErrNumber, mscMODULE & ":" & scSOURCE, sErrDescription
    End If
End Function

Private Sub Test_ExistsInCollection()
    Dim asTest As New Collection

    Debug.Assert Not ExistsInCollection(asTest, "")
    Debug.Assert Not ExistsInCollection(asTest, "xx")

    asTest.Add "item1", "key1"
    asTest.Add "item2", "key2"
    asTest.Add New Collection, "key3"
    asTest.Add Nothing, "key4"
    Debug.Assert ExistsInCollection(asTest, "key1")
    Debug.Assert ExistsInCollection(asTest, "key2")
    Debug.Assert ExistsInCollection(asTest, "key3")
    Debug.Assert ExistsInCollection(asTest, "key4")
    Debug.Assert Not ExistsInCollection(asTest, "abcx")

    Debug.Print "ExistsInCollection is okay"
End Sub

Wymaga dodatkowych korekt w przypadku, gdy elementy w kolekcji nie są obiektami, ale tablicami. Poza tym, to działało dobrze dla mnie.

Public Function CheckExists(vntIndexKey As Variant) As Boolean
    On Error Resume Next
    Dim cObj As Object

    ' just get the object
    Set cObj = mCol(vntIndexKey)

    ' here's the key! Trap the Error Code
    ' when the error code is 5 then the Object is Not Exists
    CheckExists = (Err <> 5)

    ' just to clear the error
    If Err <> 0 Then Call Err.Clear
    Set cObj = Nothing
End Function

_{Źródło: http://coderstalk.blogspot.com/2007/09/visual-basic-programming-how-to-check.html}

W przypadku, gdy klucz jest nieużywany do pobrania:

Public Function Contains(col As Collection, thisItem As Variant) As   Boolean

  Dim item As Variant

  Contains = False
  For Each item In col
    If item = thisItem Then
      Contains = True
      Exit Function
    End If
  Next
End Function

Nie Mój kod, ale myślę, że jest ładnie napisany. Umożliwia sprawdzanie zarówno przy pomocy klucza, jak i samego elementu obiektu i obsługuje zarówno metodę błędu On, jak i iterację przez wszystkie elementy kolekcji.

Https://danwagner.co/how-to-check-if-a-collection-contains-an-object/

Nie skopiuję pełnego wyjaśnienia, ponieważ jest ono dostępne na linkowanej stronie. Samo rozwiązanie skopiowane na wypadek, gdyby strona ostatecznie stała się niedostępna w przyszłości.

The wątpliwość mam co do kodu jest overusage GoTo w pierwszym bloku If ale to jest łatwe do naprawienia dla każdego, więc zostawiam oryginalny kod jak jest.

'''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
'INPUT       : Kollection, the collection we would like to examine
'            : (Optional) Key, the Key we want to find in the collection
'            : (Optional) Item, the Item we want to find in the collection
'OUTPUT      : True if Key or Item is found, False if not
'SPECIAL CASE: If both Key and Item are missing, return False
Option Explicit
Public Function CollectionContains(Kollection As Collection, Optional Key As Variant, Optional Item As Variant) As Boolean
    Dim strKey As String
    Dim var As Variant

    'First, investigate assuming a Key was provided
    If Not IsMissing(Key) Then

        strKey = CStr(Key)

        'Handling errors is the strategy here
        On Error Resume Next
            CollectionContains = True
            var = Kollection(strKey) '<~ this is where our (potential) error will occur
            If Err.Number = 91 Then GoTo CheckForObject
            If Err.Number = 5 Then GoTo NotFound
        On Error GoTo 0
        Exit Function

CheckForObject:
        If IsObject(Kollection(strKey)) Then
            CollectionContains = True
            On Error GoTo 0
            Exit Function
        End If

NotFound:
        CollectionContains = False
        On Error GoTo 0
        Exit Function

    'If the Item was provided but the Key was not, then...
    ElseIf Not IsMissing(Item) Then

        CollectionContains = False '<~ assume that we will not find the item

        'We have to loop through the collection and check each item against the passed-in Item
        For Each var In Kollection
            If var = Item Then
                CollectionContains = True
                Exit Function
            End If
        Next var

    'Otherwise, no Key OR Item was provided, so we default to False
    Else
        CollectionContains = False
    End If

End Function

Zrobiłem tak, wariacja na temat kodu Vadims, ale dla mnie trochę bardziej czytelna:

' Returns TRUE if item is already contained in collection, otherwise FALSE

Public Function Contains(col As Collection, item As String) As Boolean

    Dim i As Integer

    For i = 1 To col.Count

    If col.item(i) = item Then
        Contains = True
        Exit Function
    End If

    Next i

    Contains = False

End Function

Napisałam ten kod. To może komuś pomóc...

Public Function VerifyCollection()
    For i = 1 To 10 Step 1
       MyKey = "A"
       On Error GoTo KillError:
       Dispersao.Add 1, MyKey
       GoTo KeepInForLoop
KillError: 'If My collection already has the key A Then...
        count = Dispersao(MyKey)
        Dispersao.Remove (MyKey)
        Dispersao.Add count + 1, MyKey 'Increase the amount in relationship with my Key
        count = Dispersao(MyKey) 'count = new amount
        On Error GoTo -1
KeepInForLoop:
    Next
End Function