XSLT-Usuń białe znaki z szablonu

Domyślnie szablony XSLT mają ustawione <xsl:preserve-space>, które zachowają białe znaki w wynikach. Możesz dodać <xsl:strip-space elements="*">, aby powiedzieć gdzie usunąć białe znaki.

Może być również konieczne dołączenie dyrektywy normalize-space, w ten sposób:

<xsl:template match="text()"><xsl:value-of select="normalize-space(.)"/></xsl:template> 

Oto przykład zachowania / usunięcia przestrzeni ze szkół W3.

Jeśli chodzi o usuwanie tabulatorów, ale zachowując oddzielne linie, wypróbowałem następujące podejście XSLT 1.0 i działa dość dobrze. Korzystanie z wersji 1.0 lub 2.0 w dużej mierze zależy od używanej platformy. Wygląda na to, że technologia. NET jest nadal zależna od XSLT 1.0, a więc jesteś ograniczony do bardzo niechlujnych szablonów(patrz poniżej). Jeśli używasz Javy lub czegoś innego, zapoznaj się z dużo czystszym podejściem XSLT 2.0 wymienionym na samym dole.

Te przykłady mają na celu być rozszerzone przez Ciebie w celu spełnienia Twoich specyficznych potrzeb. Używam tabs tutaj jako przykład, ale to powinno być na tyle ogólne, aby być rozszerzalne.

XML:

<?xml version="1.0" encoding="UTF-8"?>
<text>
        adslfjksdaf

                dsalkfjdsaflkj

            lkasdfjlsdkfaj
</text>

...i szablon XSLT 1.0 (wymagany, jeśli używasz. NET):

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet  
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">   
 <xsl:template name="search-and-replace">
   <xsl:param name="input"/>
   <xsl:param name="search-string"/>
   <xsl:param name="replace-string"/>
   <xsl:choose>
    <xsl:when test="$search-string and 
                    contains($input,$search-string)">
       <xsl:value-of
           select="substring-before($input,$search-string)"/>
       <xsl:value-of select="$replace-string"/>
       <xsl:call-template name="search-and-replace">
         <xsl:with-param name="input"
               select="substring-after($input,$search-string)"/>
         <xsl:with-param name="search-string"
               select="$search-string"/>
         <xsl:with-param name="replace-string"
               select="$replace-string"/>
       </xsl:call-template>
    </xsl:when>
    <xsl:otherwise>
      <xsl:value-of select="$input"/>
    </xsl:otherwise>
   </xsl:choose>
  </xsl:template>                
  <xsl:template match="text">
   <xsl:call-template name="search-and-replace">
     <xsl:with-param name="input" select="text()" />
     <xsl:with-param name="search-string" select="'&#x9;'" />
     <xsl:with-param name="replace-string" select="''" />
   </xsl:call-template>    
  </xsl:template>
</xsl:stylesheet>

XSLT 2.0 czyni to trywialnym za pomocą funkcji replace:

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
      xmlns:xs="http://www.w3.org/2001/XMLSchema"
      exclude-result-prefixes="xs"
      version="2.0">
 <xsl:template match="text">
  <xsl:value-of select="replace(text(), '&#x9;', '')" />
 </xsl:template>
</xsl:stylesheet>

Inni już zwrócili uwagę na ogólny problem. Specyficznym dla Twojego arkusza stylów jest to, że zapomniałeś <xsl:text> o przecinkach:

   <xsl:choose>
    <xsl:when test="@TYPE">
     <xsl:value-of select="@TYPE" />,
    </xsl:when>
    <xsl:otherwise>Home </xsl:otherwise>
   </xsl:choose>
   <xsl:value-of select="STREET" />,
   <xsl:value-of select="CITY" />,
   <xsl:value-of select="STATE" />,
   <xsl:value-of select="ZIP" />,

To sprawia, że spacje po przecinku są znaczące, a więc kończy się na wyjściu. Jeśli zawijasz każdy przecinek w <xsl:text>, problem znika.

Pozbądź się też tego disable-output-escaping. Tutaj nic nie robi, ponieważ nie wysyłasz XML.

Dodaj jeden szablon do swojego xslt

<xsl:template match="text()"/>

Moja poprzednia odpowiedź jest błędna, wszystkie przecinki muszą być wypisane przez tag 'text'

<?xml version="1.0" ?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="text"/>
    <xsl:template match="/PHONEBOOK">
        <xsl:for-each select="LISTING">
            <xsl:value-of select="RELATION" /><xsl:text>, </xsl:text>
            <xsl:value-of select="FIRST" /><xsl:text>, </xsl:text>
            <xsl:value-of select="LAST" /><xsl:text>, </xsl:text>

                <xsl:for-each select="ADDRESS">
                    <xsl:choose>
                        <xsl:when test="@TYPE">
                            <xsl:value-of select="@TYPE" /><xsl:text>,</xsl:text>
                        </xsl:when>
                        <xsl:otherwise><xsl:text>Home </xsl:text></xsl:otherwise>
                    </xsl:choose>
                <xsl:value-of select="STREET/text()" /><xsl:text>,</xsl:text>
                    <xsl:value-of select="CITY/text()" /><xsl:text>,</xsl:text>
                    <xsl:value-of select="STATE/text()" /><xsl:text>,</xsl:text>
                    <xsl:value-of select="ZIP/text()" /><xsl:text>,</xsl:text>
                </xsl:for-each>

            <xsl:for-each select="PHONE">
                <xsl:choose>
                    <xsl:when test="@TYPE">
                        <xsl:value-of select="@TYPE" />  
                    </xsl:when>
                    <xsl:otherwise><xsl:text>Home </xsl:text></xsl:otherwise>
                </xsl:choose>
                <xsl:value-of select="."  /><xsl:text  >, </xsl:text>
            </xsl:for-each>

            <xsl:if test="EMAIL">
                <xsl:for-each select="EMAIL">
                    <xsl:choose>
                        <xsl:when test="@TYPE">
                            <xsl:value-of select="@TYPE" /><xsl:text  > </xsl:text> 
                        </xsl:when>
                        <xsl:otherwise><xsl:text  >Personal </xsl:text></xsl:otherwise>
                    </xsl:choose>
                    <xsl:value-of select="."  /><xsl:text  >, </xsl:text>
                </xsl:for-each>
            </xsl:if>
            <xsl:text>&#10;&#13;</xsl:text>
        </xsl:for-each>
    </xsl:template>
    <xsl:template match="text()|@*">
        <xsl:text>-</xsl:text>
    </xsl:template>

</xsl:stylesheet>

Zmodyfikuj kod, którego użyliśmy do formatowania surowego pliku xml, usuwając poniższe linie, usunie dodatkowe puste białe spacje dodane w eksportowanym Excelu.

Podczas formatowania z wciętą właściwością system dodaje te dodatkowe puste białe spacje.

Skomentuj wiersze związane z formatowaniem xml jak poniżej i spróbuj.

xmlWriter.Formatting = System.Xml.Formatting.Indented;