Podświetl zmienną pod kursorem w Vimie tak jak w NetBeans

Jeśli ustawisz

:set hlsearch

Aby podświetlić wszystkie wystąpienia wzorca wyszukiwania, a następnie użyć * lub #, aby znaleźć wystąpienie słowa pod kursorem, które zapewni Ci jakiś sposób na to, co chcesz. Myślę jednak, że podświetlanie zmiennych świadomych składni wykracza poza zakres Vima.

To polecenie pozwoli zmiennej włączyć / wyłączyć podświetlanie wszystkich wystąpień słowa pod kursorem:

:autocmd CursorMoved * exe exists("HlUnderCursor")?HlUnderCursor?printf('match IncSearch /\V\<%s\>/', escape(expand('<cword>'), '/\')):'match none':""

Można aktywować podświetlenie za pomocą:

:let HlUnderCursor=1

I wyłącz go za pomocą:

:let HlUnderCursor=0

Można łatwo zdefiniować klawisz skrótu do włączania / wyłączania podświetlania:

:nnoremap <silent> <F3> :exe "let HlUnderCursor=exists(\"HlUnderCursor\")?HlUnderCursor*-1+1:1"<CR>

Usunięcie zmiennej uniemożliwiłoby wykonanie polecenia match i nie wyczyściłoby bieżącego podświetlenia:

:unlet HlUnderCursor

Jeśli nie chcesz wyróżniać słów językowych (wypowiedzi / preprocesy takie jak if, #define) gdy kursor znajduje się na tych słowach, możesz umieścić tę funkcję w swoim .vimrc na podstawie odpowiedzi @too_much_php:

let g:no_highlight_group_for_current_word=["Statement", "Comment", "Type", "PreProc"]
function s:HighlightWordUnderCursor()
    let l:syntaxgroup = synIDattr(synIDtrans(synID(line("."), stridx(getline("."), expand('<cword>')) + 1, 1)), "name")

    if (index(g:no_highlight_group_for_current_word, l:syntaxgroup) == -1)
        exe printf('match IncSearch /\V\<%s\>/', escape(expand('<cword>'), '/\'))
    else
        exe 'match IncSearch /\V\<\>/'
    endif
endfunction

autocmd CursorMoved * call s:HighlightWordUnderCursor()

Myślę, że to, czego naprawdę chcesz, to następujący plugin Shuhei Kubota:

Http://www.vim.org/scripts/script.php?script_id=4306

Zgodnie z opisem: 'ten skrypt podświetla słowa pod kursorem jak wiele IDE.'

Zdrówko.

vim_current_word działa po wyjęciu z pudełka, jest świadomy składni i umożliwia konfigurowanie kolorów.

Aby odwzorować F2, aby przełączyć podświetlenie:

map <F2> :set hlsearch!<CR> * #

Ten wariant jest zoptymalizowany pod kątem szybkości (używa CursorHold zamiast CursorMoved)i kompatybilności z hlsearch. Bieżące podświetlanie słowa wyszukiwania nie zostanie przerwane.

" autosave delay, cursorhold trigger, default: 4000ms
setl updatetime=300

" highlight the word under cursor (CursorMoved is inperformant)
highlight WordUnderCursor cterm=underline gui=underline
autocmd CursorHold * call HighlightCursorWord()
function! HighlightCursorWord()
    " if hlsearch is active, don't overwrite it!
    let search = getreg('/')
    let cword = expand('<cword>')
    if match(cword, search) == -1
        exe printf('match WordUnderCursor /\V\<%s\>/', escape(cword, '/\'))
    endif
endfunction

Podobne do zaakceptowanej odpowiedzi, ale w ten sposób można ustawić czas opóźnienia po przytrzymaniu kursora nad Słowem, zanim pojawi się podświetlenie. 1000 jest w milisekundach i oznacza, że podświetli się po 1 sekundzie.

set updatetime=1000

autocmd CursorHold * exe 
    \ printf('match IncSearch /\V\<%s\>/', escape(expand('<cword>'), '/\'))

Zobacz :h CursorHold aby uzyskać więcej informacji.