Jak Sprawdzić w AppleScript, czy aplikacja jest uruchomiona, bez jej uruchamiania-za pomocą narzędzia osascript

Niektóre Informacje:

"Rozszerzony Model Obiektowy Aplikacji":

tell application "iTunes"
    if it is running then
      pause
    end if
end tell

Możesz też to zrobić w ten sposób:

if application "iTunes" is running then
    tell application "iTunes" to quit
end if

get name of application "iTunes"
get version of application "iTunes"

I aby ukończyć podróż:

get id of application "TextEdit" --> "com.apple.TextEdit"
tell application id "com.apple.TextEdit"
    make new document
end tell

To był "ulepszony model obiektowy aplikacji". Jeśli aplikacja nadal uruchamia się (na przykład, po raz pierwszy skompilować & wykonać skrypt) zakładam, że to dlatego, że AS ma uzyskać pewne informacje z aplikacji, które nie znaleziono w słowniku (lub coś w tym stylu...?).

OK, wiem, że to pytanie jest naprawdę stare, ale natknąłem się na nie szukając innego problemu i musiałem się spieszyć, biorąc pod uwagę, jak skomplikowane są niektóre z tych odpowiedzi.

Prosty kod do osiągnięcia tego,co chcesz (ed) to:

tell application "System Events"
  if application process "Safari" exists then
    -- do stuff you want to do only if Safari exists
  end if
end tell

W starszych systemach składnia używana to:

tell application "System Events"
  if exists of application process "Safari" is true then
    -- do stuff you want to do only if Safari exists
  end if
end tell

Jeden z nich powinien zdecydowanie działać dla Ciebie, nieustraszony poszukiwacz rozwiązań Applescript do działania tylko wtedy, gdy aplikacja jest uruchomiona.

Oh! Bonus wskazówka: a jeśli nie jesteś pewien, jaka jest dokładnie Nazwa procesu aplikacji (jest to Zwykle, ale nie zawsze Nazwa aplikacji), przed zakodowaniem ostatecznego skryptu Uruchom ...

tell application "System Events"
   get every application process
end tell

I znajdź nazwę procesu aplikacji w wynikach.

tell application "Finder"
    set applicationsnames to get the name of every process whose visible is true
end tell

set appName to "Safari"

if applicationsnames does not contain appName then
    say (appName & " is not running")
    --add here what you want to happen

end if
return applicationsnames

This is return {"Finder", "JavaAppLauncher", "firefox", "Microsoft Word", "iTunes", "AppleScript Editor"} for me

Hope this helps

Wszystkie wcześniej wykonane odpowiedzi cierpią z tego samego problemu, choć:

Szukają aplikacji po jej nazwie. Jednak użytkownik może zmienić nazwę aplikacji, a następnie skrypt uwierzy, że aplikacja nie działa, podczas gdy w rzeczywistości tak.

Aby prawidłowo sprawdzić, czy uruchomiona aplikacja, powinna być znaleziona po identyfikatorze pakietu, którego Użytkownik nie może zmienić.

Identyfikator pakietu może być zapytany za pomocą tego polecenia, na przykład:

tell application "System Events"
    get bundle identifier of application process "Safari"
end tell

Aby sprawdzić, czy aplikacja z określonym pakietem ID działa, użyj tego kodu:

tell application "System Events"
    set ids to bundle identifier of every application process
    if ids contains "com.apple.safari" then
        return "Running"
    else
        return "Not running"
    end if
end tell

Ponadto, oto przykład, aby sprawdzić, czy aplikacja jest uruchomiona, a następnie zamknąć ją, a następnie uruchomić ponownie, upewniając się, że ta sama aplikacja jest ponownie uruchomiona przed, a nie jakaś inna kopia, która może również istnieć:

set bundleID to "com.apple.safari"
set apps to runningApps(bundleID)
set appCount to length of apps
if appCount is not 0 then
    quit application id bundleID
    repeat while length of runningApps(bundleID) = appCount
        -- wait for the app to quit
    end repeat
    open first item of apps
end if

on runningApps(bundleID)
    -- The try block is to catch the rare case of having more than one
    -- copy of an app running at the same time. Unfortunately, in that
    -- case this code will not run as expected, because we don't get the
    -- correct list of multiple items back then. But at least the script
    -- will not crash from it but handle it gracefully.
    tell application "System Events"
        try
            return application file of (every application process whose bundle identifier = bundleID)
        end try
    end tell
    return {}
end runningApps

Miałem ten sam problem, jak opisano tutaj, próbując skonfigurować AppleScript (wyzwalany gestem BetterTouchTool), który odtwarza / zatrzymuje VLC lub iTunes, ale tylko iTunes, jeśli VLC nie jest uruchomiony (z powodu mojego przepływu pracy) i, oczywiście, tylko VLC, gdy jest uruchomiony. (Używam automatycznego wyzwalacza pauzy/odtwarzania dla iTunes w Ustawieniach VLC, do uruchamiania i zamykania aplikacji.)

VLC był zawsze uruchamiany przy pierwszym użyciu wyzwalacza BetterTouchTool po każdym ponownym uruchomieniu BTT, ponieważ dictionary-cache jest usunięte w tym momencie, a obsługa AppleScript musi uruchomić każdą aplikację skryptową, jeśli tell jest skierowany do niej, aby wywołać jej słownik.

Nigdzie nie znalazłem niczego, co mogłoby tego uniknąć; były pewne próby, ale żadna nie zadziałała dla mnie, ponieważ wywołanie słownika przez obsługę skryptu nie jest niczym, na co możemy mieć wpływ. Wymyśliłem to brudne obejście:

• Utwórz oddzielny plik AppleScript zawierający tylko linię, która zawiera tell dla VLC
• Save it w jakimś miejscu, gdzie nie będzie cię to denerwować
• Zastąp linię zawierającą tell w oryginalnym Applescripcie linią uruchamiającą ten skrypt

Spowoduje to, że pierwsza Kompilacja skryptu nie wywoła aplikacji (VLC, w moim przypadku) bezpośrednio, tylko skrypt, co oznacza, że aplikacja nie będzie musiała się uruchamiać.

VLC będzie musiał uruchomić po wywołaniu oddzielnego pliku, ale cóż, jeśli wywołasz ten plik, aby powiedzieć coś VLC, czy VLC jest już otwarty (lub będzie chciał go otworzyć) tak czy inaczej.

AppleScript, który wywołuję przez mój BetterTouchTool-trigger (konkretne dotknięcie na gładziku, w moim przypadku) wygląda tak:

if application "iTunes" is running and not application "VLC" is running then
tell application "iTunes" to playpause

End if jeżeli aplikacja" VLC " jest uruchomiona to uruchom skrypt " / Users/jannis/bin / PlayVLC.scpt" end if

Oddzielny plik AppleScript ("PLayVLC.scpt, zapisany w folderze o nazwie "bin" w moim folderze użytkownika, który utworzyłem ręcznie wieki temu do takich celów) jest właśnie taki:

tell application "VLC" to play

Jeśli jeśli otworzysz ten skrypt ręcznie, To oczywiście uruchomi on również VLC. Ale mam nadzieję, że nie będzie to konieczne często,ani nigdy.

Właściwie nie mam pojęcia, czy stwarza to jakieś głębsze problemy, o których Nie wiem, ponieważ nie jestem pro koderem; jeśli tak, proszę mnie powiadomić. Mam nadzieję, że to komuś pomoże!