Jak używać modeli z QML?

Aby nawet zacząć rozwiązywać twój problem, musimy zobaczyć, co robi metoda unitGenerator. Jeśli używasz modelu niestandardowego, jest prawie pewne, że nie wdrażasz powiadomień poprawnie. Założę się, że nie sygnalizujesz resetu modelu.

Poniżej znajduje się kompletny przykład kodu, który pokazuje, jak można powiązać QStringListModel z edytowalnym ListViewi ComboBox es. Drugi model ComboBox jest regenerowany na podstawie wyboru z pierwszego. To prawdopodobnie przybliża pożądaną funkcjonalność.

Zwróć uwagę na specyficzną obsługę ról wykonywaną przez QStringListModel. Model traktuje role wyświetlania i edycji prawie tak samo: obie są mapowane do wartości łańcuchowej na liście. Jednak kiedy aktualizujesz dane konkretnej roli, sygnał dataChanged niesie tylko rolę, którą zmieniłeś. Można to wykorzystać do przerwania pętli wiążącej, która w innym przypadku może być obecna w elemencie edytora modeli (TextInput). W przypadku korzystania z modelu niestandardowego może być konieczne zaimplementuj podobną funkcjonalność.

Rola display jest używana do łączenia pól combo z modelem. Rola edit służy do wstępnego wypełniania obiektów edytora. Funkcja obsługi sygnału onTextChanged edytora aktualizuje rolę display, a to nie powoduje pętli wiążącej do siebie. Jeśli funkcja obsługi aktualizowała rolę edit, wywołałaby pętlę wiążącą za pośrednictwem właściwości text.

Na modelach w QML

Istnieją różne rodzaje "modeli" w QML. Wewnętrznie, QML zawija prawie "wszystko" w modelu. Wszystko, co jest wewnętrznie , a nie QObject , nadal może być modelem (powiedzmy QVariant), nie będzie powiadamiać nikogo o niczym.

Na przykład "model" oparty na QVariant, który owija int nie będzie wysyłać powiadomień, ponieważ QVariant nie jest QObject, które mogłyby sygnalizować zmiany.

Podobnie, jeśli twój "model" jest powiązany z wartością właściwości klasy pochodzącej z QObject, ale nie uda Ci się emit sygnału powiadomienia o zmianie właściwości, to również to nie zadziała.

Bez wiedzy, jakie są Twoje typy modelek, nie da się powiedzieć.

Main.qml

import QtQuick 2.0
import QtQuick.Controls 1.0

ApplicationWindow {
    width: 300; height: 300
    ListView {
        id: view
        width: parent.width
        anchors.top: parent.top
        anchors.bottom: column.top
        model: model1
        spacing: 2
        delegate: Component {
            Rectangle {
                width: view.width
                implicitHeight: edit.implicitHeight + 10
                color: "transparent"
                border.color: "red"
                border.width: 2
                radius: 5
                TextInput {
                    id: edit
                    anchors.margins: 1.5 * parent.border.width
                    anchors.fill: parent
                    text: edit // "edit" role of the model, to break the binding loop
                    onTextChanged: model.display = text
                }
            }
        }
    }
    Column {
        id: column;
        anchors.bottom: parent.bottom
        Text { text: "Type";  }
        ComboBox {
            id: box1
            model: model1
            textRole: "display"
            onCurrentTextChanged: generator.generate(currentText)
        }
        Text { text: "Unit"; }
        ComboBox {
            id: box2
            model: model2
            textRole: "display"
        }
    }
}

Main.cpp

#include <QGuiApplication>
#include <QQmlApplicationEngine>
#include <QQuickWindow>
#include <QStringListModel>
#include <QQmlContext>

class Generator : public QObject
{
    Q_OBJECT
    QStringListModel * m_model;
public:
    Generator(QStringListModel * model) : m_model(model) {}
    Q_INVOKABLE void generate(const QVariant & val) {
        QStringList list;
        for (int i = 1; i <= 3; ++i) {
            list << QString("%1:%2").arg(val.toString()).arg(i);
        }
        m_model->setStringList(list);
    }
};

int main(int argc, char *argv[])
{
    QStringListModel model1, model2;
    Generator generator(&model2);
    QGuiApplication app(argc, argv);
    QQmlApplicationEngine engine;

    QStringList list;
    list << "one" << "two" << "three" << "four";
    model1.setStringList(list);

    engine.rootContext()->setContextProperty("model1", &model1);
    engine.rootContext()->setContextProperty("model2", &model2);
    engine.rootContext()->setContextProperty("generator", &generator);

    engine.load(QUrl("qrc:/main.qml"));
    QObject *topLevel = engine.rootObjects().value(0);
    QQuickWindow *window = qobject_cast<QQuickWindow *>(topLevel);
    window->show();
    return app.exec();
}

#include "main.moc"