Jak uzyskać bieżącą datetime w wierszu poleceń systemu Windows, w odpowiednim formacie do użycia w nazwie pliku?

Regionalnie niezależne parsowanie daty i czasu

Format wyjściowy %DATE% i dir jest zależny regionalnie, a więc ani solidny, ani inteligentny. Data.exe (część UnxUtils) dostarcza dowolne informacje o dacie i czasie w dowolnym formacie. Możesz również wyodrębnić informacje o dacie/godzinie z dowolnego pliku za pomocą date.exe.

date.exe +"%Y-%m-%d"
2009-12-22

date.exe +"%T"
18:55:03

date.exe +"%Y%m%d %H%M%S: Any text"
20091222 185503: dowolny tekst

date.exe +"Text: %y/%m/%d-any text-%H.%M"
Tekst: 09/12/22-dowolny tekst-18.55

Command: date.exe +"%m-%d """%H %M %S """"
07-22 "18:55:03"`

Informacje o dacie/godzinie z pliku referencyjnego:
date.exe -r c:\file.txt +"The timestamp of file.txt is: %Y-%m-%d %H:%M:%S"

for /f "tokens=1,2,3,4,5,6* delims=," %%i in ('C:\Tools\etc\date.exe +"%%y,%%m,%%d,%%H,%%M,%%S"') do set yy=%%i& set mo=%%j& set dd=%%k& set hh=%%l& set mm=%%m& set ss=%%n

for /f "tokens=*" %%i in ('C:\Tools\etc\date.exe +"%%y-%%m-%%d %%H:%%M:%%S"') do set timestamp=%%i

Wydobywanie informacji o dacie/czasie z dowolnego odniesienia plik.

for /f "tokens=1,2,3,4,5,6* delims=," %%i in ('C:\Tools\etc\date.exe -r file.txt +"%%y,%%m,%%d,%%H,%%M,%%S"') do set yy=%%i& set mo=%%j& set dd=%%k& set hh=%%l& set mm=%%m& set ss=%%n

Dodanie do pliku informacji o dacie/godzinie:

for /f "tokens=*" %%i in ('C:\Tools\etc\date.exe -r file.txt +"%%y-%%m-%%d.%%H%%M%%S"') do ren file.txt file.%%i.txt

Data.exe jest czÄ ™ Ĺ " ciÄ ... wolnych narzÄ ™ dzi GNU, ktĂłre nie wymagajÄ ... instalacji.

Uwaga: skopiowanie date.exe do dowolnego katalogu, który znajduje się w ścieżce wyszukiwania, może spowodować awarię innych skryptów, które używają wbudowanego w system Windows polecenia date.

Jeszcze dwa sposoby, które nie zależą od ustawień czasu(oba pobrane z : Jak uzyskać DANE / czas niezależnie od lokalizacji: ). I oba dostają również Dzień tygodnia i żaden z nich nie wymaga uprawnień administratora!:

1. MAKECAB - będzie działać na każdym systemie Windows (szybko, ale tworzy mały plik tymczasowy) (skrypt foxidrive):

   @echo off
   pushd "%temp%"
   makecab /D RptFileName=~.rpt /D InfFileName=~.inf /f nul >nul
   for /f "tokens=3-7" %%a in ('find /i "makecab"^<~.rpt') do (
      set "current-date=%%e-%%b-%%c"
      set "current-time=%%d"
      set "weekday=%%a"
   )
   del ~.*
   popd
   echo %weekday% %current-date% %current-time%
   pause
   

   Więcej informacji o funkcji get-date .

2. ROBOCOPY - nie jest to natywne polecenie Dla Windows XP i Windows Server 2003, ale można je pobrać ze strony microsoft site . Ale jest wbudowany we wszystko od Windows Vista i wyżej:

   @echo off
   setlocal
   for /f "skip=8 tokens=2,3,4,5,6,7,8 delims=: " %%D in ('robocopy /l * \ \ /ns /nc /ndl /nfl /np /njh /XF * /XD *') do (
    set "dow=%%D"
    set "month=%%E"
    set "day=%%F"
    set "HH=%%G"
    set "MM=%%H"
    set "SS=%%I"
    set "year=%%J"
   )
   
   echo Day of the week: %dow%
   echo Day of the month : %day%
   echo Month : %month%
   echo hour : %HH%
   echo minutes : %MM%
   echo seconds : %SS%
   echo year : %year%
   endlocal
   

   I jeszcze trzy sposoby, które używają innych języków skryptowych Windows. Dadzą ci większą elastyczność, np. możesz uzyskać tydzień roku, Czas w milisekundach i tak dalej.

3. JScript / batch hybrid (należy zapisać jako .bat). JScript jest dostępny w każdym systemie NT i nowsze, jako część Windows Script Host (choć może być wyłączony przez rejestr jest to rzadki przypadek):

   @if (@X)==(@Y) @end /* ---Harmless hybrid line that begins a JScript comment
   
   @echo off
   cscript //E:JScript //nologo "%~f0"
   exit /b 0
   *------------------------------------------------------------------------------*/
   
   function GetCurrentDate() {
           // Today date time which will used to set as default date.
           var todayDate = new Date();
           todayDate = todayDate.getFullYear() + "-" +
                          ("0" + (todayDate.getMonth() + 1)).slice(-2) + "-" +
                          ("0" + todayDate.getDate()).slice(-2) + " " + ("0" + todayDate.getHours()).slice(-2) + ":" +
                          ("0" + todayDate.getMinutes()).slice(-2);
   
           return todayDate;
       }
   
   WScript.Echo(GetCurrentDate());
   

4. Vscript / BATCH hybrid (czy możliwe jest osadzenie i wykonanie VBScript w pliku wsadowym bez użycia pliku tymczasowego?) ten sam przypadek co JScript, ale hybrydyzacja nie jest tak doskonała:

   :sub echo(str) :end sub
   echo off
   '>nul 2>&1|| copy /Y %windir%\System32\doskey.exe %windir%\System32\'.exe >nul
   '& echo current date:
   '& cscript /nologo /E:vbscript "%~f0"
   '& exit /b
   
   '0 = vbGeneralDate - Default. Returns date: mm/dd/yy and time if specified: hh:mm:ss PM/AM.
   '1 = vbLongDate - Returns date: weekday, monthname, year
   '2 = vbShortDate - Returns date: mm/dd/yy
   '3 = vbLongTime - Returns time: hh:mm:ss PM/AM
   '4 = vbShortTime - Return time: hh:mm
   
   WScript.echo  Replace(FormatDateTime(Date,1),", ","-")
   

5. PowerShell - może być zainstalowany na każdym komputerze, który ma. NET - Pobierz z Microsoft (v1, v2, v3 (tylko dla Windows 7 i nowszych)). Jest instalowany domyślnie na wszystkich systemach Windows 7 / Windows Server 2008 i nowszych:

   C:\> powershell get-date -format "{dd-MMM-yyyy HH:mm}"
   

   Aby użyć go z pliku wsadowego:

   for /f "delims=" %%# in ('powershell get-date -format "{dd-MMM-yyyy HH:mm}"') do @set _date=%%#
   

6. SELF-compiled jscript.net/batch [[20]} (nigdy nie widziałem komputera z systemem Windows bez. Net, więc myślę, że jest to dość przenośny):

   @if (@X)==(@Y) @end /****** silent line that start JScript comment ******
   
   @echo off
   ::::::::::::::::::::::::::::::::::::
   :::       Compile the script    ::::
   ::::::::::::::::::::::::::::::::::::
   setlocal
   if exist "%~n0.exe" goto :skip_compilation
   
   set "frm=%SystemRoot%\Microsoft.NET\Framework\"
   
   :: Searching the latest installed .NET framework
   for /f "tokens=* delims=" %%v in ('dir /b /s /a:d /o:-n "%SystemRoot%\Microsoft.NET\Framework\v*"') do (
       if exist "%%v\jsc.exe" (
           rem :: the javascript.net compiler
           set "jsc=%%~dpsnfxv\jsc.exe"
           goto :break_loop
       )
   )
   echo jsc.exe not found && exit /b 0
   :break_loop
   
   
   call %jsc% /nologo /out:"%~n0.exe" "%~dpsfnx0"
   ::::::::::::::::::::::::::::::::::::
   :::       End of compilation    ::::
   ::::::::::::::::::::::::::::::::::::
   :skip_compilation
   
   "%~n0.exe"
   
   exit /b 0
   
   
   ****** End of JScript comment ******/
   import System;
   import System.IO;
   
   var dt=DateTime.Now;
   Console.WriteLine(dt.ToString("yyyy-MM-dd hh:mm:ss"));
   

7. Logman to nie może uzyskać roku i dnia tygodnia. Jest stosunkowo wolny, a także tworzy plik tymczasowy i opiera się na znacznikach Czasu, które logman umieszcza w swoich plikach dziennika. Będzie działać na wszystkim od Windows XP i wyżej. Prawdopodobnie nigdy nie będzie używany przez nikogo-w tym mnie - ale jest jeszcze jeden sposób...

   @echo off
   setlocal
   del /q /f %temp%\timestampfile_*
   
   Logman.exe stop ts-CPU 1>nul 2>&1
   Logman.exe delete ts-CPU 1>nul 2>&1
   
   Logman.exe create counter ts-CPU  -sc 2 -v mmddhhmm -max 250 -c "\Processor(_Total)\%% Processor Time" -o %temp%\timestampfile_ >nul
   Logman.exe start ts-CPU 1>nul 2>&1
   
   Logman.exe stop ts-CPU >nul 2>&1
   Logman.exe delete ts-CPU >nul 2>&1
   for /f "tokens=2 delims=_." %%t in  ('dir /b %temp%\timestampfile_*^&del /q/f %temp%\timestampfile_*') do set timestamp=%%t
   
   echo %timestamp%
   echo MM: %timestamp:~0,2%
   echo dd: %timestamp:~2,2%
   echo hh: %timestamp:~4,2%
   echo mm: %timestamp:~6,2%
   
   endlocal
   exit /b 0
   

8. Jeszcze jeden sposób z WMIC który również podaje tydzień roku i Dzień tygodnia, ale nie milisekund (dla milisekund sprawdź odpowiedź foxidrive):

   for /f %%# in ('wMIC Path Win32_LocalTime Get /Format:value') do @for /f %%@ in ("%%#") do @set %%@
   echo %day%
   echo %DayOfWeek%
   echo %hour%
   echo %minute%
   echo %month%
   echo %quarter%
   echo %second%
   echo %weekinmonth%
   echo %year%
   

9. Za pomocą TYPEPERF z pewnymi wysiłkami, aby być szybkim i zgodnym z różnymi ustawieniami językowymi i tak szybko, jak to możliwe:

   @echo off
   setlocal
   
   :: Check if Windows is Windows XP and use Windows XP valid counter for UDP performance
   ::if defined USERDOMAIN_roamingprofile (set "v=v4") else (set "v=")
   
   for /f "tokens=4 delims=. " %%# in ('ver') do if %%# GTR 5 (set "v=v4") else ("v=")
   set "mon="
   for /f "skip=2 delims=," %%# in ('typeperf "\UDP%v%\*" -si 0 -sc 1') do (
      if not defined mon (
         for /f "tokens=1-7 delims=.:/ " %%a in (%%#) do (
           set mon=%%a
           set date=%%b
           set year=%%c
           set hour=%%d
           set minute=%%e
           set sec=%%f
           set ms=%%g
         )
      )
   )
   echo %year%.%mon%.%date%
   echo %hour%:%minute%:%sec%.%ms%
   endlocal
   

10. MSHTA umożliwia wywołanie metod JavaScript podobnych do metody JScript zademonstrowanej w #3 powyżej. Należy pamiętać, że właściwości obiektu date JavaScript zawierające wartości miesiąca są ponumerowane od 0 do 11, a nie od 1 do 12. Zatem wartość 9 oznacza październik.

    <!-- : Batch portion
    
    @echo off
    setlocal
    
    for /f "delims=" %%I in ('mshta "%~f0"') do set "now.%%~I"
    
    rem Display all variables beginning with "now."
    set now.
    
    goto :EOF
    
    end batch / begin HTA -->
    
    <script>
        resizeTo(0,0)
        var fso = new ActiveXObject('Scripting.FileSystemObject').GetStandardStream(1),
            now = new Date(),
            props=['getDate','getDay','getFullYear','getHours','getMilliseconds','getMinutes',
                'getMonth','getSeconds','getTime','getTimezoneOffset','getUTCDate','getUTCDay',
                'getUTCFullYear','getUTCHours','getUTCMilliseconds','getUTCMinutes','getUTCMonth',
                'getUTCSeconds','getYear','toDateString','toGMTString','toLocaleDateString',
                'toLocaleTimeString','toString','toTimeString','toUTCString','valueOf'],
            output = [];
    
        for (var i in props) {output.push(props[i] + '()=' + now[props[i]]())}
        close(fso.Write(output.join('\n')));
    </script>
    

Oto wariant z alt.msdos.Nr serii.nt, który działa lokalnie-niezależnie.

Umieść to w pliku tekstowym, np. getDate.cmd

-----------8<------8<------------ snip -- snip ----------8<-------------
    :: Works on any NT/2k machine independent of regional date settings
    @ECHO off
    SETLOCAL ENABLEEXTENSIONS
    if "%date%A" LSS "A" (set toks=1-3) else (set toks=2-4)
    for /f "tokens=2-4 delims=(-)" %%a in ('echo:^|date') do (
      for /f "tokens=%toks% delims=.-/ " %%i in ('date/t') do (
        set '%%a'=%%i
        set '%%b'=%%j
        set '%%c'=%%k))
    if %'yy'% LSS 100 set 'yy'=20%'yy'%
    set Today=%'yy'%-%'mm'%-%'dd'% 
    ENDLOCAL & SET v_year=%'yy'%& SET v_month=%'mm'%& SET v_day=%'dd'%

    ECHO Today is Year: [%V_Year%] Month: [%V_Month%] Day: [%V_Day%]

    :EOF
-----------8<------8<------------ snip -- snip ----------8<-------------

Aby Kod działał bez błędów msg na stderr, musiałem dodać pojedyncze cudzysłowy arount przypisania zmiennych dla % % a, % % b i %%c. moje locale (PT) powodowało błędy na jednym etapie w pętli / parsingu, gdzie rzeczy takie jak "set =20" były wykonywane. Cytaty dają token (choć pusty) dla lewej strony przypisania oświadczenie.

Minusem są niechlujne nazwy zmiennych lokalnych: 'yy', ' mm ' i 'dd'. Ale kogo to obchodzi!

I use this (again not region independent (UK))

set bklog=%date:~6,4%-%date:~3,2%-%date:~0,2%_%time:~0,2%%time:~3,2%

Niestety nie jest to Odporne na ustawienia regionalne, ale robi to, co chcesz.

set hour=%time:~0,2%
if "%time:~0,1%"==" " set hour=0%time:~1,1%
set _my_datetime=%date:~10,4%-%date:~4,2%-%date:~7,2%_%hour%%time:~3,2%

Niesamowite rzeczy, które można znaleźć na Wikipedii .

Proszę użyć następującego skryptu, aby uzyskać bieżący dzień w wierszu poleceń:

echo %Date:~0,3%day

Pierwsze cztery linie tego kodu dadzą ci wiarygodne zmienne YY DD MM RRRR HH Min sec w Windows XP Professional i wyższych.

@echo off
for /f "tokens=2 delims==" %%a in ('wmic OS Get localdatetime /value') do set "dt=%%a"
set "YY=%dt:~2,2%" & set "YYYY=%dt:~0,4%" & set "MM=%dt:~4,2%" & set "DD=%dt:~6,2%"
set "HH=%dt:~8,2%" & set "Min=%dt:~10,2%" & set "Sec=%dt:~12,2%"

set "datestamp=%YYYY%%MM%%DD%" & set "timestamp=%HH%%Min%%Sec%" & set "fullstamp=%YYYY%-%MM%-%DD%_%HH%%Min%-%Sec%"
echo datestamp: "%datestamp%"
echo timestamp: "%timestamp%"
echo fullstamp: "%fullstamp%"
pause

Another way (kredyt):

@For /F "tokens=2,3,4 delims=/ " %%A in ('Date /t') do @( 
    Set Month=%%A
    Set Day=%%B
    Set Year=%%C
)

@echo DAY = %Day%
@echo Month = %Month%
@echo Year = %Year%

Zauważ, że obie moje odpowiedzi są nadal zależne od kolejności dnia i miesiąca, określonej przez ustawienia regionalne - Nie wiem, jak to obejść.

"d:\Program Files\7-Zip\7z.exe" a -r code_%date:~10,4%-%date:~4,2%-%date:~7,2%.zip

To nie jest tak naprawdę krótsze, ale może być bardziej elastyczny sposób ( kredyt):

FOR /F "TOKENS=1* DELIMS= " %%A IN ('DATE/T') DO SET CDATE=%%B
FOR /F "TOKENS=1,2 eol=/ DELIMS=/ " %%A IN ('DATE/T') DO SET mm=%%B
FOR /F "TOKENS=1,2 DELIMS=/ eol=/" %%A IN ('echo %CDATE%') DO SET dd=%%B
FOR /F "TOKENS=2,3 DELIMS=/ " %%A IN ('echo %CDATE%') DO SET yyyy=%%B
SET date=%mm%%dd%%yyyy%

Oto sposób, aby uzyskać czas daty w jednej linii:

for /f "tokens=2,3,4,5,6 usebackq delims=:/ " %a in ('%date% %time%') do echo %c-%a-%b %d%e

W USA wyświetli się "RRRR-MM-dd hhmm". Różne ustawienia regionalne spowodują różne wyniki %date%, ale możesz zmodyfikować kolejność tokenów.

Jeśli chcesz zmienić format, zmodyfikuj instrukcję echo, zmieniając tokeny lub używając innych (lub nie) separatorów.

Krótka odpowiedź:

 :: Start - Run , type:
 cmd /c "powershell get-date -format ^"{yyyy-MM-dd HH:mm:ss}^"|clip"

 :: click into target media, Ctrl + V to paste the result 

Długa odpowiedź

    @echo off
    :: START USAGE  ==================================================================
    ::SET THE NICETIME 
    :: SET NICETIME=BOO
    :: CALL GetNiceTime.cmd 

    :: ECHO NICETIME IS %NICETIME%

    :: echo nice time is %NICETIME%
    :: END USAGE  ==================================================================

    echo set hhmmsss
    :: this is Regional settings dependant so tweak this according your current settings
    for /f "tokens=1-3 delims=:" %%a in ('echo %time%') do set hhmmsss=%%a%%b%%c 
    ::DEBUG ECHO hhmmsss IS %hhmmsss%
    ::DEBUG PAUSE
    echo %yyyymmdd%
        :: this is Regional settings dependant so tweak this according your current settings
    for /f "tokens=1-3 delims=." %%D in ('echo %DATE%') do set  yyyymmdd=%%F%%E%%D
    ::DEBUG ECHO yyyymmdd IS %yyyymmdd%
    ::DEBUG PAUSE


    set NICETIME=%yyyymmdd%_%hhmmsss%
    ::DEBUG echo THE NICETIME IS %NICETIME%

    ::DEBUG PAUSE

I tutaj jest podobny plik wsadowy dla porcji czasu.

:: http://stackoverflow.com/questions/203090/how-to-get-current-datetime-on-windows-command-line-in-a-suitable-format-for-usi
:: Works on any NT/2k machine independent of regional time settings
::
:: Gets the time in ISO 8601 24-hour format
::
:: Note that %time% gets you fractions of seconds, and time /t doesn't, but gets you AM/PM if your locale supports that.
:: Since ISO 8601 does not care about AM/PM, we use %time%
::
    @ECHO off
    SETLOCAL ENABLEEXTENSIONS
    for /f "tokens=1-4 delims=:,.-/ " %%i in ('echo %time%') do (
      set 'hh'=%%i
      set 'mm'=%%j
      set 'ss'=%%k
      set 'ff'=%%l)
    ENDLOCAL & SET v_Hour=%'hh'%& SET v_Minute=%'mm'%& SET v_Second=%'ss'%& SET v_Fraction=%'ff'%

    ECHO Now is Hour: [%V_Hour%] Minute: [%V_Minute%] Second: [%v_Second%] Fraction: [%v_Fraction%]
    set timestring=%V_Hour%%V_Minute%%v_Second%.%v_Fraction%
    echo %timestring%

    :EOF

--jeroen

Zmieniłem odpowiedź z pliku wsadowego z vMax więc działa również z językiem niderlandzkim.
Holendrzy-wytrwali jak my-mają kilka zmian w %date%, date/t, i date które łamią oryginalny plik wsadowy.

Byłoby miło, gdyby niektórzy ludzie mogli sprawdzić to również w innych lokalizacjach Windows i zgłosić wyniki.
Jeśli plik wsadowy zawiedzie w Twojej lokalizacji, dołącz do polecenia wynik tych dwóch instrukcji prompt:
echo:^|date
date/t

Jest to próbka wyjścia, które powinieneś uzyskać z pliku wsadowego:

C:\temp>set-date-cmd.bat
Today is Year: [2011] Month: [01] Day: [03]
20110103

Oto poprawiony kod z komentarzami dlaczego:

:: https://stackoverflow.com/questions/203090/how-to-get-current-datetime-on-windows-command-line-in-a-suitable-format-for-usi
:: Works on any NT/2k machine independent of regional date settings
::
:: 20110103 - adapted by [email protected] for Dutch locale
:: Dutch will get jj as year from echo:^|date, so the '%%c' trick does not work as it will fill 'jj', but we want 'yy'
:: luckily, all countries seem to have year at the end: http://en.wikipedia.org/wiki/Calendar_date
::            set '%%c'=%%k
::            set 'yy'=%%k
::
:: In addition, date will display the current date before the input prompt using dashes
:: in Dutch, but using slashes in English, so there will be two occurances of the outer loop in Dutch
:: and one occurence in English.
:: This skips the first iteration:
::        if "%%a" GEQ "A"
::
:: echo:^|date
:: Huidige datum: ma 03-01-2011
:: Voer de nieuwe datum in: (dd-mm-jj)
:: The current date is: Mon 01/03/2011
:: Enter the new date: (mm-dd-yy)
::
:: date/t
:: ma 03-01-2011
:: Mon 01/03/2011
::
:: The assumption in this batch-file is that echo:^|date will return the date format
:: using either mm and dd or dd and mm in the first two valid tokens on the second line, and the year as the last token.
::
:: The outer loop will get the right tokens, the inner loop assigns the variables depending on the tokens.
:: That will resolve the order of the tokens.
::
@ECHO off
    set v_day=
    set v_month=
    set v_year=

    SETLOCAL ENABLEEXTENSIONS
    if "%date%A" LSS "A" (set toks=1-3) else (set toks=2-4)
::DEBUG echo toks=%toks%
      for /f "tokens=2-4 delims=(-)" %%a in ('echo:^|date') do (
::DEBUG echo first token=%%a
        if "%%a" GEQ "A" (
          for /f "tokens=%toks% delims=.-/ " %%i in ('date/t') do (
            set '%%a'=%%i
            set '%%b'=%%j
            set 'yy'=%%k
          )
        )
      )
      if %'yy'% LSS 100 set 'yy'=20%'yy'%
      set Today=%'yy'%-%'mm'%-%'dd'%

    ENDLOCAL & SET v_year=%'yy'%& SET v_month=%'mm'%& SET v_day=%'dd'%

    ECHO Today is Year: [%V_Year%] Month: [%V_Month%] Day: [%V_Day%]
    set datestring=%V_Year%%V_Month%%V_Day%
    echo %datestring%

    :EOF

--jeroen

Rozwiązanie Matthew Johnsona jednoliniowe , Aby uzyskać jednoliniową datę i godzinę, jest wymowne i użyteczne.

Wymaga jednak prostej modyfikacji, aby działać z poziomu pliku wsadowego:

for /f "tokens=2,3,4,5,6 usebackq delims=:/ " %%a in ('%date% %time%') do echo %%c-%%a-%%b %%d%%e

Po prostu użyj tej linii:

PowerShell -Command "get-date"

Funkcja oparta na wmic:

:Now  -- Gets the current date and time into separate variables
::    %~1: [out] Year
::    %~2: [out] Month
::    %~3: [out] Day
::    %~4: [out] Hour
::    %~5: [out] Minute
::    %~6: [out] Second
  setlocal
  for /f %%t in ('wmic os get LocalDateTime ^| findstr /b [0-9]') do set T=%%t
  endlocal & (
    if "%~1" neq "" set %~1=%T:~0,4%
    if "%~2" neq "" set %~2=%T:~4,2%
    if "%~3" neq "" set %~3=%T:~6,2%
    if "%~4" neq "" set %~4=%T:~8,2%
    if "%~5" neq "" set %~5=%T:~10,2%
    if "%~6" neq "" set %~6=%T:~12,2%
  )
goto:eof

Strona główna: Region niezależny. minus: Tylko administratorzy systemu mogą uruchomić wmic.exe.

Użycie:

call:Now Y M D H N S
echo %Y%-%M%-%D% %H%:%N%:%S%

To echos taki ciąg:

2014-01-22 12:51:53

Zauważ, że parametry funkcji nie są parametrami-to znaczy, musisz podać nazwy zmiennych zamiast wartości.

Wszystkie parametry są opcjonalne, więc {[4] } jest prawidłowym wywołaniem, jeśli chcesz uzyskać tylko rok i miesiąc.

Tego użyłem:

::Date Variables - replace characters that are not legal as part of filesystem file names (to produce name like "backup_04.15.08.7z")
SET DT=%date%
SET DT=%DT:/=.%
SET DT=%DT:-=.%

Jeśli potrzebujesz dalszych pomysłów na automatyzację kopii zapasowych do archiwów 7-Zip, mam darmowy / otwarty projekt, który możesz wykorzystać lub przejrzeć pod kątem pomysłów: http://wittman.org/ziparcy/

Miałem podobny problem. Mam automatyczne codzienne pobieranie z serwera FTP zaszyfrowanego pliku. Chciałem odszyfrować plik za pomocą gpg, zmienić nazwę pliku na aktualną datę (format RRRRMMDD) i wrzucić odszyfrowany plik do folderu właściwego działu.

Przejrzałem kilka propozycji zmiany nazwy pliku zgodnie z datą i nie miałem szczęścia, dopóki nie natknąłem się na to proste rozwiązanie.

for /f "tokens=1-5 delims=/ " %%d in ("%date%") do rename "decrypted.txt" %%g-%%e-%%f.txt

Zadziałało idealnie (tzn. nazwa pliku wychodzi jako "2011-06-14.txt").

(Źródło)

Http://sourceforge.net/projects/unxutils/files/

Poszukaj w pliku ZIP czegoś o nazwie " Data.exe "i zmienić jego nazwę" DateFormat.exe " (aby uniknąć konfliktów).

Umieść go w folderze Windows system32.

Posiada wiele opcji "date output".

W celu uzyskania pomocy użyj DateFormat.exe --h

Nie jestem pewien, jak można umieścić jego wyjście w zmiennej środowiskowej... za pomocą zestawu.

Niezależne rozwiązanie Regionalne generujące format daty ISO:

rem save the existing format definition
for /f "skip=2 tokens=3" %%a in ('reg query "HKCU\Control Panel\International" /v sShortDate') do set FORMAT=%%a
rem set ISO specific format definition
reg add "HKCU\Control Panel\International" /v sShortDate /t REG_SZ /f /d yyyy-MM-dd 1>nul:
rem query the date in the ISO specific format 
set ISODATE=%DATE%
rem restore previous format definition
reg add "HKCU\Control Panel\International" /v sShortDate /t REG_SZ /f /d %FORMAT% 1>nul:

Co można jeszcze zoptymalizować: Inne procesy mogą się pomylić, jeśli format daty będzie używany w krótkim okresie, gdy zostanie zmodyfikowany. Tak więc parsowanie wyjścia zgodnie z istniejącym ciągiem formatów może być 'bezpieczniejsze' - ale będzie bardziej skomplikowane

:: GetDate.cmd -> Uses WMIC.exe to get current date and time in ISO 8601 format
:: - Sets environment variables %_isotime% and %_now% to current time
:: - On failure, clears these environment variables
:: Inspired on -> https://ss64.com/nt/syntax-getdate.html
:: - (cX) 2017 [email protected]
:: - http://stackoverflow.com/questions/203090
@echo off

set _isotime=
set _now=

:: Check that WMIC.exe is available
WMIC.exe Alias /? >NUL 2>&1 || goto _WMIC_MISSING_

if not (%1)==() goto _help
SetLocal EnableDelayedExpansion

:: Use WMIC.exe to retrieve date and time
FOR /F "skip=1 tokens=1-6" %%G IN ('WMIC.exe Path Win32_LocalTime Get Day^,Hour^,Minute^,Month^,Second^,Year /Format:table') DO (
    IF "%%~L"=="" goto  _WMIC_done_
        set _yyyy=%%L
        set _mm=00%%J
        set _dd=00%%G
        set _hour=00%%H
        set _minute=00%%I
        set _second=00%%K
)
:_WMIC_done_

::   1    2     3       4      5      6
:: %%G  %%H    %%I     %%J    %%K    %%L
:: Day  Hour  Minute  Month  Second  Year
:: 27   9     35      4      38      2017

:: Remove excess leading zeroes
        set _mm=%_mm:~-2%
        set _dd=%_dd:~-2%
        set _hour=%_hour:~-2%
        set _minute=%_minute:~-2%
        set _second=%_second:~-2%
:: Syntax -> %variable:~num_chars_to_skip,num_chars_to_keep%

:: Set date/time in ISO 8601 format:
        Set _isotime=%_yyyy%-%_mm%-%_dd%T%_hour%:%_minute%:%_second%
:: -> http://google.com/search?num=100&q=ISO+8601+format

if 1%_hour% LSS 112 set _now=%_isotime:~0,10% %_hour%:%_minute%:%_second%am
if 1%_hour% LSS 112 goto _skip_12_
    set /a _hour=1%_hour%-12
    set _hour=%_hour:~-2%
    set _now=%_isotime:~0,10% %_hour%:%_minute%:%_second%pm
    :: -> https://ss64.com/nt/if.html
    :: -> http://google.com/search?num=100&q=SetLocal+EndLocal+Windows
    :: 'if () else ()' will NOT set %_now% correctly !?
:_skip_12_

EndLocal & set _isotime=%_isotime% & set _now=%_now%
goto _out

:_WMIC_MISSING_
echo.
echo WMIC.exe command not available
echo - WMIC.exe needs Administrator privileges to run in Windows
echo - Usually the path to WMIC.exe is "%windir%\System32\wbem\WMIC.exe"

:_help
echo.
echo GetDate.cmd: Uses WMIC.exe to get current date and time in ISO 8601 format
echo.
echo    %%_now%%     environment variable set to current date and time
echo    %%_isotime%% environment variable to current time in ISO format
echo    set _today=%%_isotime:~0,10%%
echo.

:_out
:: EOF: GetDate.cmd

Biorąc pod uwagę znaną miejscowość, dla odniesienia w formie funkcjonalnej. Wywołanie ECHOTIMESTAMP pokazuje, jak w tym przykładzie uzyskać znacznik czasu do zmiennej (DTS.)

@ECHO off

CALL :ECHOTIMESTAMP
GOTO END

:TIMESTAMP
SETLOCAL  EnableDelayedExpansion
    SET DATESTAMP=!DATE:~10,4!-!DATE:~4,2!-!DATE:~7,2!
    SET TIMESTAMP=!TIME:~0,2!-!TIME:~3,2!-!TIME:~6,2!
    SET DTS=!DATESTAMP: =0!-!TIMESTAMP: =0!
ENDLOCAL & SET "%~1=%DTS%"
GOTO :EOF

:ECHOTIMESTAMP
SETLOCAL
    CALL :TIMESTAMP DTS
    ECHO %DTS%
ENDLOCAL
GOTO :EOF

:END

EXIT /b 0

I zapisany do pliku, znacznik czasu.bat, oto wyjście:

W Windows 7 ten kod działa dla mnie:

SET DATE=%date%
SET YEAR=%DATE:~0,4%
SET MONTH=%DATE:~5,2%
SET DAY=%DATE:~8,2%
ECHO %YEAR%
ECHO %MONTH%
ECHO %DAY%

SET DATE_FRM=%YEAR%-%MONTH%-%DAY% 
ECHO %DATE_FRM%

Wiem, że jest już wiele sposobów wymienionych. Ale oto mój sposób, aby to rozbić, aby zrozumieć, jak to się robi. Mam nadzieję, że jest to pomocne dla kogoś, kto lubi metodę krok po kroku.

:: Check your local date format
echo %date%

    :: Output is Mon 08/15/2016

:: get day (start index, number of characters)
::         (index starts with zero)
set myday=%DATE:~0,4%
echo %myday%
    :: output is Mon 

:: get month
set mymonth=%DATE:~4,2%
echo %mymonth%
    :: output is 08

:: get date 
set mydate=%DATE:~7,2% 
echo %mydate%
    :: output is 15

:: get year
set myyear=%DATE:~10,4%
echo %myyear%
    :: output is 2016