Ogólnie rzecz biorąc, nie można zmienić efektywnego identyfikatora użytkownika procesu vi, ale można to zrobić:

:w !sudo tee myfile

Wspólne Zastrzeżenie

Najczęstszą metodą obejścia problemu z plikiem tylko do odczytu jest otwarcie potoku do bieżącego pliku jako super-Użytkownik przy użyciu implementacji sudo tee. Jednak wszystkie najpopularniejsze rozwiązania, które znalazłem w Internecie, mają kombinację kilku potencjalnych zastrzeżeń: [41]}

• cały plik jest zapisywany do terminala, podobnie jak plik. Może to być powolne w przypadku dużych plików, szczególnie w powolnej sieci znajomości.
• plik traci swoje tryby i podobne atrybuty.
• ścieżki plików z nietypowymi znakami lub spacjami mogą nie być obsługiwane poprawnie.

Rozwiązania

Aby obejść wszystkie te problemy, możesz użyć następującego polecenia:

" On POSIX (Linux/Mac/BSD):
:silent execute 'write !sudo tee ' . shellescape(@%, 1) . ' >/dev/null'

" Depending on the implementation, you might need this on Windows:
:silent execute 'write !sudo tee ' . shellescape(@%, 1) . ' >NUL'

Można je skrócić, z szacunkiem:

:sil exec 'w !sudo tee ' . shellescape(@%, 1) . ' >/dev/null'
:sil exec 'w !sudo tee ' . shellescape(@%, 1) . ' >NUL'

Wyjaśnienie

: rozpoczyna polecenie; będziesz musiał wpisać ten znak w trybie normalnym, aby rozpocząć wprowadzanie polecenia. Powinno być pominięte w skryptach.

sil[ent] wyłącza wyjście z polecenia. W tym przypadku chcemy zatrzymać znak zachęty podobny do znaku Press any key to continue, który pojawia się po uruchomieniu polecenia :!.

exec[ute] wykonuje ciąg znaków jako polecenie. Nie możemy po prostu uruchomić :write, ponieważ nie przetworzy ona wymaganego wywołania funkcji.

! reprezentuje polecenie :!: jedyne polecenie, które :write akceptuje. Zwykle :write akceptuje ścieżkę do pliku, do której ma być zapisany. :! samodzielnie uruchamia polecenie w powłoce (dla przykład, używając bash -c). Z :write, uruchomi polecenie w powłoce, a następnie zapisze cały plik do stdin.

sudo to powinno być oczywiste, bo po to tu jesteś. Uruchom polecenie jako super-użytkownik. W sieci jest mnóstwo informacji o tym, jak to działa.

tee rury stdin do podanego pliku. :write zapisze do stdin, następnie super-użytkownik tee otrzyma zawartość pliku i zapisze plik. Nie utworzy nowego pliku - wystarczy nadpisać zawartość -- so tryby i atrybuty plików zostaną zachowane.

shellescape() usuwa znaki specjalne w podanej ścieżce pliku, odpowiednio dla bieżącej powłoki. Mając tylko jeden parametr, Zwykle ujmuje ścieżkę w cudzysłowie w razie potrzeby. Ponieważ wysyłamy do pełnego wiersza poleceń powłoki, będziemy chcieli przekazać niezerową wartość jako drugi argument, aby włączyć odwrotne ukośniki-ucieczki innych znaków specjalnych, które w przeciwnym razie mogłyby potknąć się o powłokę.

@% czyta zawartość rejestru %, który zawiera nazwę pliku bieżącego bufora. Niekoniecznie jest to ścieżka bezwzględna, więc upewnij się, że nie zmieniłeś bieżącego katalogu. W niektórych rozwiązaniach pojawia się symbol commercial-at pominięty. W zależności od lokalizacji, % jest poprawnym wyrażeniem i ma taki sam efekt jak odczyt rejestru %. Zagnieżdżony w innym wyrażeniu skrót jest jednak na ogół niedozwolony: na przykład w tym przypadku.

>NUL i >/dev/null przekierowanie stdout do urządzenia null platformy. Mimo że wyciszyliśmy polecenie, nie chcemy, aby wszystkie napowietrzne elementy związane z orurowaniem stdin wróciły do Vima-najlepiej zrzucić je JAK NAJSZYBCIEJ. NUL jest urządzeniem null w systemach DOS, MS-DOS i Windows, a nie prawidłowym plikiem. W systemie Windows 8 przekierowania do NUL nie skutkują zapisaniem pliku o nazwie NUL. Spróbuj utworzyć na pulpicie plik o nazwie NUL, z rozszerzeniem lub bez: nie będziesz w stanie tego zrobić. (Istnieje kilka innych nazwy urządzeń w systemie Windows, które warto poznać.)

~/.vimrc

Zależne Od Platformy

command W silent execute 'write !sudo tee ' . shellescape(@%, 1) . ' >/dev/null'

To pozwoli Ci wpisać polecenie: W (rozróżnia wielkość liter), aby zapisać bieżący plik z uprawnieniami super-user--dużo łatwiej.

Niezależny Od Platformy

Używam niezależnego od platformy pliku ~/.vimrc, który synchronizuje się między komputerami, więc dodałem funkcjonalność wieloplatformową do mojego. Oto ~/.vimrc Z tylko odpowiednimi ustawieniami:

#!vim
" Use za (not a command; the keys) in normal mode to toggle a fold.
" META_COMMENT Modeline Definition: {{{1
" vim: ts=4 sw=4 sr sts=4 fdm=marker ff=unix fenc=utf-8
"   ts:     Actual tab character stops.
"   sw:     Indentation commands shift by this much.
"   sr:     Round existing indentation when using shift commands.
"   sts:    Virtual tab stops while using tab key.
"   fdm:    Folds are manually defined in file syntax.
"   ff:     Line endings should always be <NL> (line feed #09).
"   fenc:   Should always be UTF-8; #! must be first bytes, so no BOM.


" General Commands: User Ex commands. {{{1
    command W call WriteAsSuperUser(@%)         " Write file as super-user.


" Helper Functions: Used by user Ex commands. {{{1
    function GetNullDevice() " Gets the path to the null device. {{{2
        if filewritable('/dev/null')
            return '/dev/null'
        else
            return 'NUL'
        endif
    endfunction

    function WriteAsSuperUser(file) " Write buffer to a:file as the super user (on POSIX, root). {{{2
        exec '%write !sudo tee ' . shellescape(a:file, 1) . ' >' . GetNullDevice()
    endfunction


" }}}1
" EOF

Jeśli używasz Vim , dostępny jest skrypt o nazwie sudo.vim . Jeśli odkryjesz, że otworzyłeś plik, do którego odczytu potrzebujesz dostępu roota, wpisz

:e sudo:%

Rada Ryana jest ogólnie dobra, jednak jeśli wykonasz Krok 3, nie przenoś pliku tymczasowego; będzie miał złe prawa własności i uprawnienia. Zamiast tego sudoedit poprawny plik i odczytany w treści (używając :r lub podobnych) pliku tymczasowego.

Jeśli wykonasz Krok 2, Użyj :w!, aby wymusić zapisanie pliku.

Gdy wejdziesz w tryb wstawiania na pliku, który potrzebujesz sudo access do edycji, otrzymasz komunikat o statusie:

-- INSERT -- W10: Warning: Changing a readonly file

Jeśli za tym tęsknię, generalnie to robię

:w ~/edited_blah.tmp
:q

..więc..

sudo "cat edited_blah.tmp > /etc/blah"

..albo..

sudo mv edited_blah.tmp /etc/blah

Szybkie Google daje takie rady:

1. nie próbuj edytować, jeśli jest tylko do odczytu.
2. możesz zmienić uprawnienia do pliku. (To, czy pozwoli Ci zaoszczędzić, zależy od eksperymentów.)
3. jeśli i tak nadal edytujesz, Zapisz do pliku tymczasowego, a następnie przenieś go.

Http://ubuntuforums.org/showthread.php?t=782136

Oto kolejny, który pojawił się od odpowiedzi na to pytanie, plugin o nazwie SudoEdit, który udostępnia funkcje SudoRead i SudoWrite, które domyślnie spróbują użyć sudo jako pierwszego i su, jeśli to się nie powiedzie: http://www.vim.org/scripts/script.php?script_id=2709

Mam to w moim~/.bashrc:

alias svim='sudo vim'

Teraz, gdy muszę edytować plik konfiguracyjny, otwieram go za pomocą svim.

Szybki hack, który możesz rozważyć, to wykonanie chmod na edytowanym pliku, zapisanie za pomocą Vima, a następnie chmod z powrotem do tego, co plik był pierwotnie.

ls -l test.file (to see the permissions of the file)
chmod 777 test.file
[This is where you save in vim]
chmod xxx test.file (restore the permissions you found in the first step)

Oczywiście nie polecam takiego podejścia w systemie, w którym martwisz się o bezpieczeństwo, ponieważ przez kilka sekund każdy może odczytać/zmienić plik bez Twojej wiedzy.

Użycie gksudo zamiast sudo dla GVim czyli

cmap w!! w !gksudo tee >/dev/null %