Określić układ klawiatury OS X ("źródło wejścia") w terminalu / skrypcie?

Uwaga: @MarkSetchell zasługuje na uznanie za wymyślenie fundamentalnego podejścia - gdzie [zacząć] szukać i jakich narzędzi używać. Po dalszym dochodzeniu i tam i z powrotem w komentarzach pomyślałem, że podsumuję rozwiązanie (od OS X 10.9.1): {]}

do shell script "defaults read ~/Library/Preferences/com.apple.HIToolbox.plist \\
 AppleSelectedInputSources | \\
 egrep -w 'KeyboardLayout Name' | sed -E 's/^.+ = \"?([^\"]+)\"?;$/\\1/'"

^{zauważ, jak \ jest przechowywany jako \\ na korzyść AppleScript, który zapewnia, że tylko \ dotrze do powłoki. Jeśli chcesz wykonać to samo polecenie bezpośrednio z powłoki , to be:
defaults read ~/Library/Preferences/com.apple.HIToolbox.plist AppleSelectedInputSources | egrep -w 'KeyboardLayout Name' | sed -E 's/^.+ = \"?([^\"]+)\"?;$/\1/'}

• aktualnie wybrany układ klawiatury jest przechowywany w pliku na poziomie użytkownika ~/Library/Preferences/com.apple.HIToolbox.plist, klawiszu najwyższego poziomu AppleSelectedInputSources, podkluczu KeyboardLayout Name.
• defaults read zapewnia, że bieżące ustawienia są odczytywane (niestety, od OSX 10.9, w przeciwnym razie nadrzędny /usr/libexec/PlistBuddy widzi tylko buforowaną wersję, która może być nie zsynchronizowana).
• ponieważ defaults read nie może zwrócić wartości pojedynczego klucza, wartość odsetek musi być wyodrębniona przez egrep i sed - jeden zastrzeżenie jest takie, że defaults read warunkowo używa podwójnych cudzysłowów wokół nazw kluczy i wartości łańcuchowych, w zależności od tego, czy są one pojedynczym słowem (bez interpunkcji), czy nie.

Update :

Okazuje się, że AppleScript sam może analizować listy właściwości, ale to jest trochę jak wyrywanie zębów. Ponadto, niewiarygodnie, problem potencjalnie-Nie-w pełni-aktualnych-wartości wpływa również na parsowanie AppleScript.

Poniżej znajduje się Obsługa AppleScript, która Pobiera bieżący układ klawiatury; używa obejścia opartego na do shell script, aby upewnić się, że plik plist jest aktualny, ale poza tym używa funkcji AppleScript ' s proper-list, za pomocą Property List Suite aplikacji System Events.

Uwaga: oczywiście, powyższe podejście oparte na powłoce jest znacznie krótsze w tym przypadku , ale poniższy kod pokazuje ogólne techniki pracy z listami właściwości .

# Example call.
set activeKbdLayout to my getActiveKeyboardLayout() # ->, e.g., "U.S."

on getActiveKeyboardLayout()

  # Surprisingly, using POSIX-style paths (even with '~') works with 
  # the `property list file` type.
  set plistPath to "~/Library/Preferences/com.apple.HIToolbox.plist"

  # !! First, ensure that the plist cache is flushed and that the
  # !! *.plist file contains the current value; simply executing
  # !! `default read` against the file - even with a dummy
  # !! key - does that.
  try
    do shell script "defaults read " & plistPath & " dummy"
  end try

  tell application "System Events"

    repeat with pli in property list items of ¬
      property list item "AppleSelectedInputSources" of ¬
      property list file plistPath
      # Look for (first) entry with key "KeyboardLayout Name" and return
      # its value.
      # Note: Not all entries may have a 'KeyboardLayout Name' key, 
      # so we must ignore errors.
      try
        return value of property list item "KeyboardLayout Name" of pli
      end try
    end repeat

  end tell
end getActiveKeyboardLayout