Przypisanie wyjścia programu do zmiennej

Jako dodatek do tej poprzedniej odpowiedzi, można użyć wewnątrz wyrażenia for, którego symbolem jest:

    for /f "tokens=*" %%i in ('tasklist ^| grep "explorer"') do set VAR=%%i

@OP, możesz użyć dla pętli , aby uchwycić status powrotu Twojego programu, jeśli wyświetli coś innego niż liczby

Zakładając, że wyjście aplikacji jest numerycznym kodem zwrotnym, możesz wykonać następujące czynności

application arg0 arg1
set VAR=%errorlevel%

Podczas wykonywania: for /f %%i in ('application arg0 arg1') do set VAR=%%i otrzymałem błąd: % % byłem nieoczekiwany w tym czasie. Jako fix, musiałem wykonać powyżej jako for /f %i in ('application arg0 arg1') do set VAR=%i

Oprócz odpowiedzi, nie można bezpośrednio używać operatorów przekierowań wyjściowych w set część pętli for (np. jeśli chcesz ukryć wyjście stderror przed użytkownikiem i dostarczyć ładniejszy komunikat o błędzie). Zamiast tego musisz uciec od nich z postacią karetki (^):

for /f %%O in ('some-erroring-command 2^> nul') do (echo %%O)

Reference: Redirect output of command in for loop of batch script

@echo off
SETLOCAL ENABLEDELAYEDEXPANSION

REM Prefer backtick usage for command output reading:
REM ENABLEDELAYEDEXPANSION is required for actualized
REM  outer variables within for's scope;
REM within for's scope, access to modified 
REM outer variable is done via !...! syntax.

SET CHP=C:\Windows\System32\chcp.com

FOR /F "usebackq tokens=1,2,3" %%i IN (`%CHP%`) DO (
    IF "%%i" == "Aktive" IF "%%j" == "Codepage:" (
        SET SELCP=%%k
        SET SELCP=!SELCP:~0,-1!
    )
)
echo actual codepage [%SELCP%]

ENDLOCAL

Napisałem skrypt, który pingi google.com co 5 sekund i rejestrowanie wyników z aktualnym czasem. Tutaj można znaleźć wyjście do zmiennych "commandLineStr" (z indeksami)

@echo off

:LOOPSTART

echo %DATE:~0% %TIME:~0,8% >> Pingtest.log

SETLOCAL ENABLEDELAYEDEXPANSION
SET scriptCount=1
FOR /F "tokens=* USEBACKQ" %%F IN (`ping google.com -n 1`) DO (
  SET commandLineStr!scriptCount!=%%F
  SET /a scriptCount=!scriptCount!+1
)
@ECHO %commandLineStr1% >> PingTest.log
@ECHO %commandLineStr2% >> PingTest.log
ENDLOCAL

timeout 5 > nul

GOTO LOOPSTART