Jak zastąpić wiele wzorów naraz sed?

Oto odmiana ooga ' s answer, która działa dla wielu par wyszukiwania i zamiany bez konieczności sprawdzania, jak wartości mogą być ponownie użyte:

sed -i '
s/\bAB\b/________BC________/g
s/\bBC\b/________CD________/g
s/________//g
' path_to_your_files/*.txt

Oto przykład:

Przed:

some text AB some more text "BC" and more text.

Po:

some text BC some more text "CD" and more text.

Zauważ, że \b oznacza granice słów, co uniemożliwia ________ ingerowanie w wyszukiwanie (używam GNU sed 4.2.2 na Ubuntu). Jeśli nie używasz słowa boundary search, ta technika może nie praca.

Należy również zauważyć, że daje to takie same wyniki jak usunięcie s/________//g i dodanie && sed -i 's/________//g' path_to_your_files/*.txt na koniec polecenia, ale nie wymaga dwukrotnego podania ścieżki.

Ogólną wariacją na ten temat byłoby użycie \x0 lub _\x0_ zamiast ________, jeśli wiesz, że żadne nulle nie pojawiają się w Twoich plikach, , jak zasugerował jthill.

sed jest edytorem strumieniowym. Wyszukuje i zastępuje chciwie. Jedynym sposobem, aby zrobić to, o co prosiłeś, jest użycie pośredniego wzoru substytucji i zmiana go z powrotem w końcu.

echo 'abcd' | sed -e 's/ab/xy/;s/cd/ab/;s/xy/cd/'

To może zadziałać dla Ciebie (GNU sed):

sed -r '1{x;s/^/:abbc:bcab/;x};G;s/^/\n/;:a;/\n\n/{P;d};s/\n(ab|bc)(.*\n.*:(\1)([^:]*))/\4\n\2/;ta;s/\n(.)/\1\n/;ta' file

Używa tabeli wyszukiwania, która jest przygotowywana i przechowywana w przestrzeni przytrzymania (HS), a następnie dołączana do każdej linii. Unikalny znacznik (w tym przypadku \n) jest dołączany do początku linii i używany jako metoda przebijania-wzdłuż wyszukiwania na całej długości linii. Gdy znacznik dotrze do końca wiersza, proces zostanie zakończony i zostanie wydrukowana tabela wyszukiwania i znaczniki są odrzucane.

Uwaga: tabela wyszukiwania jest przygotowywany na samym początku i drugi unikalny znacznik (w tym przypadku :) wybrany tak, aby nie kolidował z ciągami substytucyjnymi.

Z kilkoma komentarzami:

sed -r '
  # initialize hold with :abbc:bcab
  1 {
    x
    s/^/:abbc:bcab/
    x
  }

  G        # append hold to patt (after a \n)

  s/^/\n/  # prepend a \n

  :a

  /\n\n/ {
    P      # print patt up to first \n
    d      # delete patt & start next cycle
  }

  s/\n(ab|bc)(.*\n.*:(\1)([^:]*))/\4\n\2/
  ta       # goto a if sub occurred

  s/\n(.)/\1\n/  # move one char past the first \n
  ta       # goto a if sub occurred
'

Tabela działa tak:

   **   **   replacement
:abbc:bcab
 **   **     pattern

Zawsze używam wielu poleceń z "- e "

$ sed -e 's:AND:\n&:g' -e 's:GROUP BY:\n&:g' -e 's:UNION:\n&:g' -e 's:FROM:\n&:g' file > readable.sql

To dopisze '\n 'przed wszystkimi I' S, GROUP BY 's, UNION' S I FROM 's, podczas gdy' & 'oznacza dopasowany łańcuch, a' \n& 'oznacza, że chcesz zastąpić dopasowany łańcuch '\n 'przed' dopasowanym '

Tcl ma wbudowany do tego

$ tclsh
% string map {ab bc bc ab} abbc
bcab

Działa to poprzez chodzenie po łańcuchu znak w czasie robi porównywanie łańcuchów zaczynając od bieżącej pozycji.

W Perlu:

perl -E '
    sub string_map {
        my ($str, %map) = @_;
        my $i = 0;
        while ($i < length $str) {
          KEYS:
            for my $key (keys %map) {
                if (substr($str, $i, length $key) eq $key) {
                    substr($str, $i, length $key) = $map{$key};
                    $i += length($map{$key}) - 1;
                    last KEYS;
                }
            }
            $i++;
        }
        return $str;
    }
    say string_map("abbc", "ab"=>"bc", "bc"=>"ab");
'

bcab

Oto awk na podstawie oogas sed

echo 'abbc' | awk '{gsub(/ab/,"xy");gsub(/bc/,"ab");gsub(/xy/,"bc")}1'
bcab