Jak programowo wygenerować plik PDF z dowolnego dokumentu na OSX?

Spójrz na program o nazwie CUPS-PDF

Jest to wirtualna drukarka dla systemu OS X, która robi to, co robi metoda "Zapisz jako PDF" podczas drukowania za pomocą zwykłej drukarki, z wyjątkiem każdego zadania drukowania przechodzącego przez to powoduje wyjście pdf.

Po zainstalowaniu można utworzyć skrypty powłoki lub AppleScript używając lp.

Na przykład po skonfigurowaniu wirtualnej drukarki można wydrukować test.txt i mieć go automatycznie zapisać jako pdf. Aby to zrobić używając Applescriptu można użyć następującego kodu:

do shell script "lp -d CUPS_PDF test.txt"

Aplikacja cups-PDF zapisuje wszystkie dane wyjściowe do /Users/Shared / cups-PDF. Nie jestem pewien, czy można zmienić tę ścieżkę, ale można pobrać plik w skrypcie i przenieść go.

Po pierwsze, polecenie lp nie może drukować .pliki doc. Myślę, że istnieją inne aplikacje firm trzecich, które pozwolą ci to zrobić.

Po drugie, aplikacja CUPS-PDF wyświetla się w okienku Drukarki Preferencji systemowych jako posiadające myślnik w nazwie, ale CUPS pokazuje nazwę kolejki jako podkreślenie. W wierszu poleceń musisz odwołać się do nazwy kolejki CUPS_PDF z podkreśleniem.

Nawet jeśli nie jest to bardzo przydatne, aby zbudować skrypt za pomocą lp nadal chcesz korzystać ze skryptów GUI, a posiadanie wirtualnej drukarki powinno zaoszczędzić kilka kroków.

Możesz użyć takich kubków

    on open afile
        set filename to name of (info for afile)
        tell application "Finder"
            set filepath to (container of (afile as alias)) as alias
        end tell
        set filepath to quoted form of POSIX path of filepath
        set tid to AppleScript's text item delimiters
        set AppleScript's text item delimiters to "."
        set filename to text item 1 of filename
        set AppleScript's text item delimiters to tid
        set afile to quoted form of POSIX path of afile
        do shell script "cupsfilter " & afile & " > " & filepath & filename & ".pdf"
    end open

Utworzyłem alias w bash do tego:

convert2pdf() {
  /System/Library/Printers/Libraries/convert -f "$1" -o "$2" -j "application/pdf"
}

Wpisałem poniższy kod przy pomocy Automatora (nagrywając akcję, a następnie przeciągając konkretną akcję z okna "Watch Me Do", aby uzyskać Applescript). Jeśli chcesz wydrukować plik PDF z aplikacji innej niż Safari, może być konieczne uruchomienie tego samego procesu i dostosowanie tego Applescriptu wokół okna dialogowego drukowania, ponieważ każdy program może mieć inny interfejs graficzny drukowania.

# Convert the current Safari window to a PDF
# by Sebastain Gallese

# props to the following for helping me get frontmost window
# http://stackoverflow.com/questions/480866/get-the-title-of-the-current-active-window-            document-in-mac-os-x

global window_name

# This script works with Safari, you might have
# to tweak it to work with other applications 
set myApplication to "Safari"

# You can name the PDF whatever you want
# Just make sure to delete it or move it or rename it
# Before running the script again
set myPDFName to "mynewpdfile"

tell application myApplication
    activate
    if the (count of windows) is not 0 then
        set window_name to name of front window
    end if
end tell

set timeoutSeconds to 2.0
set uiScript to "keystroke \"p\" using command down"
my doWithTimeout(uiScript, timeoutSeconds)
set uiScript to "click menu button \"PDF\" of sheet 1 of window \"" & window_name & "\" of application process \"" & myApplication & "\""
my doWithTimeout(uiScript, timeoutSeconds)
set uiScript to "click menu item 2 of menu 1 of menu button \"PDF\" of sheet 1 of window \"" & window_name & "\" of application process \"" & myApplication & "\""
my doWithTimeout(uiScript, timeoutSeconds)
set uiScript to "keystroke \"" & myPDFName & "\""
my doWithTimeout(uiScript, timeoutSeconds)
set uiScript to "keystroke return"
my doWithTimeout(uiScript, timeoutSeconds)

on doWithTimeout(uiScript, timeoutSeconds)
    set endDate to (current date) + timeoutSeconds
    repeat
        try
            run script "tell application \"System Events\"
" & uiScript & "
end tell"
            exit repeat
        on error errorMessage
            if ((current date) > endDate) then
                error "Can not " & uiScript
            end if
        end try
    end repeat
end doWithTimeout