Jak skompresować (/ zip) i rozpakować (/rozpakować) pliki i foldery za pomocą pliku wsadowego bez użycia zewnętrznych narzędzi?

A oto odpowiedź (y):

1. Używanie" czystego " skryptu wsadowego do pliku zip/rozpakuj.

ZIP.CMD destination.zip source.file

I może zip tylko pojedyncze pliki.

2. Za pomocą Shell.Zastosowanie

Spędziłem trochę czasu na stworzeniu jednego hybrydowego skryptu JScript/batch do wspólnego użytku, który zamyka / rozpakowuje pliki i katalogi (plus kilka dodatkowych funkcji).oto link do niego (stał się zbyt duży, aby umieścić w odpowiedzi). Może być używany bezpośrednio z rozszerzeniem .bat i nie tworzy żadnych plików tymczasowych. Mam nadzieję, że komunikat pomocy jest wystarczająco opisowy, jak można go wykorzystać.

Niektóre przykłady:

// unzip content of a zip to given folder.content of the zip will be not preserved (-keep no).Destination will be not overwritten (-force no)
call zipjs.bat unzip -source C:\myDir\myZip.zip -destination C:\MyDir -keep no -force no

// lists content of a zip file and full paths will be printed (-flat yes)
call zipjs.bat list -source C:\myZip.zip\inZipDir -flat yes

// lists content of a zip file and the content will be list as a tree (-flat no)
call zipjs.bat list -source C:\myZip.zip -flat no

// prints uncompressed size in bytes
zipjs.bat getSize -source C:\myZip.zip

// zips content of folder without the folder itself
call zipjs.bat zipDirItems -source C:\myDir\ -destination C:\MyZip.zip -keep yes -force no

// zips file or a folder (with the folder itslelf)
call zipjs.bat zipItem -source C:\myDir\myFile.txt -destination C:\MyZip.zip -keep yes -force no

// unzips only part of the zip with given path inside
call zipjs.bat unZipItem -source C:\myDir\myZip.zip\InzipDir\InzipFile -destination C:\OtherDir -keep no -force yes
call zipjs.bat unZipItem -source C:\myDir\myZip.zip\InzipDir -destination C:\OtherDir 

// adds content to a zip file
call zipjs.bat addToZip -source C:\some_file -destination C:\myDir\myZip.zip\InzipDir -keep no
call zipjs.bat addToZip -source  C:\some_file -destination C:\myDir\myZip.zip

Niektóre znane problemy podczas zapinania:

• jeśli nie ma wystarczającej ilości miejsca na dysku systemowym (Zwykle C:) skrypt może powodować różne błędy , najczęściej skrypt się zatrzymuje.Jest to spowodowane Shell.Aplikacja aktywnie używa folderu %TEMP% do kompresji/dekompresji danych.
• foldery i pliki zawierające symbole unicode w swoich nazwach nie mogą być obsługiwane przez powłokę.Obiekt aplikacji.
• maksymalny obsługiwany rozmiar produkowanych plików zip to około 8gb w Vista i nowszych oraz około 2gb W XP / 2003

Skrypt wykrywa, czy wyskakuje komunikat o błędzie i zatrzymuje wykonanie i informuje o możliwej reasons.At w tej chwili nie mam możliwości wykrycia tekstu wewnątrz wyskakującego i podania dokładnej przyczyny awarii.

3. Makecab

Kompresja pliku jest łatwa - makecab file.txt "file.cab" . Ostatecznie MaxCabinetSize może być zwiększona. Kompresowanie folderu wymaga dyrektywy usage DestinationDir (z ścieżki względne) dla każdego (pod)katalogu i plików wewnątrz . Oto skrypt:

;@echo off

;;;;; rem start of the batch part  ;;;;;
;
;for %%a in (/h /help -h -help) do ( 
;   if /I "%~1" equ "%%~a" if "%~2" equ "" (
;       echo compressing directory to cab file  
;       echo Usage:
;       echo(
;       echo %~nx0 "directory" "cabfile"
;       echo(
;       echo to uncompress use:
;       echo EXPAND cabfile -F:* .
;       echo(
;       echo Example:
;       echo(
;       echo %~nx0 "c:\directory\logs" "logs"
;       exit /b 0
;   )
; )
;
; if "%~2" EQU "" (
;   echo invalid arguments.For help use:
;   echo %~nx0 /h
;   exit /b 1
;)
;
; set "dir_to_cab=%~f1"
;
; set "path_to_dir=%~pn1"
; set "dir_name=%~n1" 
; set "drive_of_dir=%~d1"
; set "cab_file=%~2"
;
; if not exist %dir_to_cab%\ (
;   echo no valid directory passed
;   exit /b 1
;)

;
;break>"%tmp%\makecab.dir.ddf"
;
;setlocal enableDelayedExpansion
;for /d /r "%dir_to_cab%" %%a in (*) do (
;   
;   set "_dir=%%~pna"
;   set "destdir=%dir_name%!_dir:%path_to_dir%=!"
;   (echo(.Set DestinationDir=!destdir!>>"%tmp%\makecab.dir.ddf")
;   for %%# in ("%%a\*") do (
;       (echo("%%~f#"  /inf=no>>"%tmp%\makecab.dir.ddf")
;   )
;)
;(echo(.Set DestinationDir=!dir_name!>>"%tmp%\makecab.dir.ddf")
;   for %%# in ("%~f1\*") do (
;       
;       (echo("%%~f#"  /inf=no>>"%tmp%\makecab.dir.ddf")
;   )

;makecab /F "%~f0" /f "%tmp%\makecab.dir.ddf" /d DiskDirectory1=%cd% /d CabinetNameTemplate=%cab_file%.cab
;rem del /q /f "%tmp%\makecab.dir.ddf"
;exit /b %errorlevel%

;;
;;;; rem end of the batch part ;;;;;

;;;; directives part ;;;;;
;;
.New Cabinet
.set GenerateInf=OFF
.Set Cabinet=ON
.Set Compress=ON
.Set UniqueFiles=ON
.Set MaxDiskSize=1215751680;

.set RptFileName=nul
.set InfFileName=nul

.set MaxErrors=1
;;
;;;; end of directives part ;;;;;

Przykładowe użycie:

call cabDir.bat ./myDir compressedDir.cab

Do dekompresji EXPAND cabfile -F:* . mogą być użyte.Do ekstrakcji w systemie Unix można użyć cabextractlub 7zip.

4. . NET i GZipStream

Wolałem Jscript.net ponieważ pozwala na zgrabną hybrydyzację z .bat (brak toksycznych danych wyjściowych i brak plików temp).Jscript nie pozwala na przekazywanie referencji obiektu do funkcji, więc jedynym sposobem, w jaki znalazłem spraw, aby działało to przez odczyt / zapis plików bajt po bajcie (więc przypuszczam, że nie jest to najszybszy sposób - jak można wykonać buforowany Odczyt / Zapis?) Ponownie może być używany tylko z pojedynczymi plikami.

@if (@X)==(@Y) @end /* JScript comment
@echo off
setlocal

for /f "tokens=* delims=" %%v in ('dir /b /s /a:-d  /o:-n "%SystemRoot%\Microsoft.NET\Framework\*jsc.exe"') do (
   set "jsc=%%v"
)

if not exist "%~n0.exe" (
    "%jsc%" /nologo /out:"%~n0.exe" "%~dpsfnx0"
)

 %~n0.exe %*

endlocal & exit /b %errorlevel%


*/


import System;
import System.Collections.Generic;
import System.IO;
import System.IO.Compression;


    
    function CompressFile(source,destination){
        var sourceFile=File.OpenRead(source);
        var destinationFile=File.Create(destination);
        var output = new  GZipStream(destinationFile,CompressionMode.Compress);
        Console.WriteLine("Compressing {0} to {1}.", sourceFile.Name,destinationFile.Name, false);
        var byteR = sourceFile.ReadByte();
        while(byteR !=- 1){
            output.WriteByte(byteR);
            byteR = sourceFile.ReadByte();
        }
        sourceFile.Close();
        output.Flush();
        output.Close();
        destinationFile.Close();
    }

    function UncompressFile(source,destination){
        var sourceFile=File.OpenRead(source);
        var destinationFile=File.Create(destination);
        
        var input = new GZipStream(sourceFile,
            CompressionMode.Decompress, false);
        Console.WriteLine("Decompressing {0} to {1}.", sourceFile.Name,
                destinationFile.Name);
        
        var byteR=input.ReadByte();
        while(byteR !== -1){
            destinationFile.WriteByte(byteR);
            byteR=input.ReadByte();
        }
        destinationFile.Close();
        input.Close();
        
        
    }
    
var arguments:String[] = Environment.GetCommandLineArgs();

    function printHelp(){
        Console.WriteLine("Compress and uncompress gzip files:");
        Console.WriteLine("Compress:");
        Console.WriteLine(arguments[0]+" -c source destination");
        Console.WriteLine("Uncompress:");
        Console.WriteLine(arguments[0]+" -u source destination");
        
        
    }

if (arguments.length!=4){
    Console.WriteLine("Wrong arguments");
    printHelp();
    Environment.Exit(1);
}

switch (arguments[1]){
    case "-c":
    
        CompressFile(arguments[2],arguments[3]);
        break;
    case "-u":
        UncompressFile(arguments[2],arguments[3]);
        break;
    default:
        Console.WriteLine("Wrong arguments");
        printHelp();
        Environment.Exit(1);
}

Przykładowe użycie:

//zip
call netzip.bat -c my.file my.zip
//unzip
call netzip.bat -u my.zip my.file

5. TAR (tylko dla najnowszych wersji Windows)

Z najnowszymi kompilacjami windows 10 mamy teraz polecenie TAR , choć nie jest to najbardziej kompatybilna wstecz opcja:

//compress directory
tar -cvf archive.tar c:\my_dir
//extract to dir
tar -xvf archive.tar.gz -C c:\data