Jak ustawić rozmiar czcionki w Emacsie?

Z Emacswiki , GNU Emacs 23 ma wbudowaną kombinację klawiszy:

C-xC - + i C-xC-- aby zwiększyć lub zmniejsz rozmiar tekstu bufora

Naciśnij Shift i pierwszy przycisk myszy. Możesz zmienić rozmiar czcionki w następujący sposób: Ta strona ma więcej szczegółów.

m-x customize-face Ret default pozwoli Ci ustawić Twarz default, na której opierają się wszystkie inne twarze. Tam możesz ustawić rozmiar czcionki.

;; my colour theme is whateveryouwant :)
(require 'color-theme)
(color-theme-initialize)
(color-theme-whateveryouwant)

(custom-set-faces
  ;; custom-set-faces was added by Custom.
  ;; If you edit it by hand, you could mess it up, so be careful.
  ;; Your init file should contain only one such instance.
  ;; If there is more than one, they won't work right.
 '(default ((t (:stipple nil :background "white" :foreground "black" :inverse-video nil :box nil :strike-through nil :overline nil :underline nil :slant normal :weight normal :height 98 :width normal :foundry "unknown" :family "DejaVu Sans Mono"))))
 '(font-lock-comment-face ((t (:foreground "darkorange4"))))
 '(font-lock-function-name-face ((t (:foreground "navy"))))
 '(font-lock-keyword-face ((t (:foreground "red4"))))
 '(font-lock-type-face ((t (:foreground "black"))))
 '(linum ((t (:inherit shadow :background "gray95"))))
 '(mode-line ((t (nil nil nil nil :background "grey90" (:line-width -1 :color nil :style released-button) "black" :box nil :width condensed :foundry "unknown" :family "DejaVu Sans Mono")))))

To kolejne proste rozwiązanie. Działa również w 24

(set-default-font "Monaco 14")

Skróty:

`C-+` increases font size
`C--` Decreases font size

Mam w moim .emacs:

(defun fontify-frame (frame)
  (set-frame-parameter frame 'font "Monospace-11"))

;; Fontify current frame
(fontify-frame nil)
;; Fontify any future frames
(push 'fontify-frame after-make-frame-functions) 

Możesz zastąpić dowolną czcionkę "Monospace-11". Zestaw dostępnych opcji jest w dużym stopniu zależny od systemu. Używanie M-x set-default-font i przeglądanie zakładki-completions da ci kilka pomysłów. W moim systemie, z włączonym Emacs 23 i anti-aliasing, można wybrać czcionki systemowe według nazwy, np., Monospace, Sans Serif, itd.

Otwórz emacs w X11, przejdź do opcji menu, wybierz " Ustaw domyślną czcionkę ...", Zmień rozmiar czcionki. Wybierz "Zapisz opcje" w tym samym menu. Załatwione.

Firefox i inne programy pozwalają na zwiększenie i zmniejszenie rozmiaru czcionki za pomocą C - + i C--. Ustawiłem swoje .emacs tak, że mam taką samą możliwość dodając te linie kodu:

(global-set-key [C-kp-add] 'text-scale-increase)

(global-set-key [C-kp-subtract] 'text-scale-decrease)

Zoom.cfg i global-zoom.cfg Podaj ustawienia zmiany rozmiaru czcionki (z EmacsWiki)

C -- lub C-mousewheel-up: zwiększa rozmiar czcionki.
• C- + lub C-mousewheel-down: zmniejsza rozmiar czcionki.
• C-0 przywraca domyślny rozmiar czcionki.

Oto opcja interaktywnej zmiany rozmiaru wysokości czcionek, jeden punkt na raz:

;; font sizes
(global-set-key (kbd "s-=")
                (lambda ()
                  (interactive)
                  (let ((old-face-attribute (face-attribute 'default :height)))
                    (set-face-attribute 'default nil :height (+ old-face-attribute 10)))))

(global-set-key (kbd "s--")
                (lambda ()
                  (interactive)
                  (let ((old-face-attribute (face-attribute 'default :height)))
                    (set-face-attribute 'default nil :height (- old-face-attribute 10)))))

Jest to korzystne, gdy chcesz zmienić rozmiar tekstu w wszystkich buforach. Nie lubię rozwiązań wykorzystujących text-scale-increase i text-scale-decrease, ponieważ numery linii w rynnie mogą zostać później odcięte.

Wszystko zależy co masz na myśli zmieniając rozmiar czcionki. Ta sekcja EmacsWiki dostarcza najlepszych i najbardziej kompletnych informacji. Rozróżnia różne przypadki (skalowanie tekstu, czcionka ramki, bufor / ramka, itp.): Zmiana Rozmiaru Czcionki .

Jestem zadowolony z konsoli emacs( emacs-nw), nowoczesne implementacje vterm (jak gnome-terminal) mają lepsze wsparcie dla czcionek. Dodatkowo, jeśli się do tego przyzwyczaisz, możesz użyć tmux, a więc praca z pełnym środowiskiem na zdalnych serwerach staje się możliwa, nawet bez X.

W AquaMacs CMD + i CMD - Dostosuj rozmiar czcionki dla bieżącego bufora.

Aquamacs :

(set-face-attribute 'default nil :font "Monaco-16" )

Z Emacs Wiki globalnie Zmień domyślną czcionkę, mówi, że możesz użyć jednej z nich:

(set-face-attribute 'default nil :font FONT )

(set-frame-font FONT nil t)

Gdzie FONT jest czymś w rodzaju "Monaco-16", np.:

(set-face-attribute 'default nil :font "Monaco-16" )

W pierwszej sugestii na wiki pojawił się dodatkowy nawias zamykający, który spowodował błąd podczas uruchamiania. W końcu zauważyłem dodatkowy nawias zamykający, a następnie poprawiłem sugestię na wiki. Wtedy obie sugestie zadziałały dla mnie.

W NTEmacs 23.1, menu Opcje ma "Ustaw domyślną czcionkę..."opcja.

Używam pakietu hydra do kontrolowania zwiększania/zmniejszania czcionki przez naciśnięcie f2 + + + +/f2 - - - -, co oznacza, że naciśnięcie f2 raz, a następnie użycie +/- aby tylko kontrolować i przywrócić domyślny rozmiar czcionki przez f2 0. Ponieważ mam klawiaturę, więc również przypisuję klawiaturę do Ustawienia czcionki.

(defhydra hydra-zoom (global-map "<f2>")
  "zoom"
  ("<kp-add>" text-scale-increase "in")
  ("+" text-scale-increase "in")
  ("-" text-scale-decrease "out")
  ("<kp-subtract>" text-scale-decrease "out")
  ("0" (text-scale-set 0) "reset")
  ("<kp-0>" (text-scale-set 0) "reset"))

I nowoczesna funkcja sterowania myszą edytora obsługiwana przez poniższe powiązania klawiszy, naciśnij klawisz control + kółko myszy, aby zwiększyć / zmniejszyć czcionkę.

(global-set-key (kbd "<C-wheel-up>") 'text-scale-increase)
(global-set-key (kbd "<C-wheel-down>") 'text-scale-decrease)

Oto fragment, który pozwala bezpośrednio określić globalny rozmiar czcionki za pomocą funkcji interaktywnej:

(defun set-font-size ()
    "Set the font size."
  (interactive)
  (set-face-attribute
   'default nil :height
   (string-to-number
    (read-string "Font size: " (number-to-string (face-attribute 'default :height nil))))))