Jak zresetować sekwencję w Oracle?
W PostgreSQL mogę zrobić coś takiego:
ALTER SEQUENCE serial RESTART WITH 0;
Czy istnieje odpowiednik wyroczni? 17 answers
Oto dobra procedura resetowania dowolnej sekwencji do 0 z Oracle Guru Tom Kyte . Świetna dyskusja na temat plusów i minusów w linkach poniżej.
[email protected]>
create or replace
procedure reset_seq( p_seq_name in varchar2 )
is
l_val number;
begin
execute immediate
'select ' || p_seq_name || '.nextval from dual' INTO l_val;
execute immediate
'alter sequence ' || p_seq_name || ' increment by -' || l_val ||
' minvalue 0';
execute immediate
'select ' || p_seq_name || '.nextval from dual' INTO l_val;
execute immediate
'alter sequence ' || p_seq_name || ' increment by 1 minvalue 0';
end;
/
Z tej strony: dynamiczny SQL do resetowania wartości Sekwencji
Kolejna dobra dyskusja jest również tutaj: Jak zresetować sekwencje?
Warning: date(): Invalid date.timezone value 'Europe/Kyiv', we selected the timezone 'UTC' for now. in /var/www/agent_stack/data/www/doraprojects.net/template/agent.layouts/content.php on line 54
2008-09-18 15:34:52
Prawdziwy restart nie jest możliwy AFAIK . (Popraw mnie, jeśli się mylę!).
Jeśli jednak chcesz ustawić go na 0, możesz go po prostu usunąć i odtworzyć.
Jeśli chcesz ustawić ją na określoną wartość, możesz ustawić przyrost na wartość ujemną i uzyskać następną wartość.
Oznacza to, że jeśli twoja Sekwencja wynosi 500, możesz ustawić ją na 100 przez
ALTER SEQUENCE serial INCREMENT BY -400;
SELECT serial.NEXTVAL FROM dual;
ALTER SEQUENCE serial INCREMENT BY 1;
Warning: date(): Invalid date.timezone value 'Europe/Kyiv', we selected the timezone 'UTC' for now. in /var/www/agent_stack/data/www/doraprojects.net/template/agent.layouts/content.php on line 54
2017-06-23 18:14:06
Oto moje podejście:
- upuść sekwencję
- odtworzyć
Przykład:
--Drop sequence
DROP SEQUENCE MY_SEQ;
-- Create sequence
create sequence MY_SEQ
minvalue 1
maxvalue 999999999999999999999
start with 1
increment by 1
cache 20;
Warning: date(): Invalid date.timezone value 'Europe/Kyiv', we selected the timezone 'UTC' for now. in /var/www/agent_stack/data/www/doraprojects.net/template/agent.layouts/content.php on line 54
2012-04-08 14:17:09
Moje podejście jest małym rozszerzeniem przykładu Dougmana .
Rozszerzenia są...
Podaj wartość ziarna jako parametr. Dlaczego? Lubię wywoływać Resetowanie sekwencji z powrotem do maksymalnego identyfikatora używanego w jakiejś tabeli . W końcu wywołuję ten proc z innego skryptu, który wykonuje wiele wywołań dla całej grupy sekwencji, resetując nextval z powrotem do poziomu, który jest wystarczająco wysoki, aby nie spowodować naruszenia klucza głównego, gdzie używam sekwencji wartość niepowtarzalnego identyfikatora.
Uwzględnia również poprzednią wartość minvalue. Może w rzeczywistości przesunąć kolejną wartość coraz wyższą, jeśli żądana p_val lub istniejąca minvalue jest wyższa niż bieżąca lub obliczona Następna wartość.
Najlepsze ze wszystkich, może być wywołany, aby zresetować do określonej wartości, i po prostu czekać, aż zobaczysz procedurę wrapper "fix all my sequences" na końcu.
create or replace
procedure Reset_Sequence( p_seq_name in varchar2, p_val in number default 0)
is
l_current number := 0;
l_difference number := 0;
l_minvalue user_sequences.min_value%type := 0;
begin
select min_value
into l_minvalue
from user_sequences
where sequence_name = p_seq_name;
execute immediate
'select ' || p_seq_name || '.nextval from dual' INTO l_current;
if p_Val < l_minvalue then
l_difference := l_minvalue - l_current;
else
l_difference := p_Val - l_current;
end if;
if l_difference = 0 then
return;
end if;
execute immediate
'alter sequence ' || p_seq_name || ' increment by ' || l_difference ||
' minvalue ' || l_minvalue;
execute immediate
'select ' || p_seq_name || '.nextval from dual' INTO l_difference;
execute immediate
'alter sequence ' || p_seq_name || ' increment by 1 minvalue ' || l_minvalue;
end Reset_Sequence;
Ta procedura jest przydatna sama w sobie, ale teraz dodajmy jeszcze jedną, która ją wywołuje i określa wszystko programowo z konwencją nazewnictwa sekwencji i szuka maksymalnej wartości użytej w istniejącej tabeli / polu...
create or replace
procedure Reset_Sequence_to_Data(
p_TableName varchar2,
p_FieldName varchar2
)
is
l_MaxUsed NUMBER;
BEGIN
execute immediate
'select coalesce(max(' || p_FieldName || '),0) from '|| p_TableName into l_MaxUsed;
Reset_Sequence( p_TableName || '_' || p_Fieldname || '_SEQ', l_MaxUsed );
END Reset_Sequence_to_Data;
Teraz gotujemy na gazie!
Powyższa procedura sprawdza maksymalną wartość pola w tabeli, buduje nazwę sekwencji z pary tabela / pole i wywołuje "Reset_Sequence" z tą wyczuwalną wartością maksymalną.
Ostatni element tej układanki i wisienka na torcie następny...
create or replace
procedure Reset_All_Sequences
is
BEGIN
Reset_Sequence_to_Data( 'ACTIVITYLOG', 'LOGID' );
Reset_Sequence_to_Data( 'JOBSTATE', 'JOBID' );
Reset_Sequence_to_Data( 'BATCH', 'BATCHID' );
END Reset_All_Sequences;
W mojej bazie danych jest około stu innych sekwencji resetowanych za pomocą tego mechanizmu, więc jest jeszcze 97 wywołań Reset_Sequence_to_Data w powyższej procedurze.
Podoba Ci się? Nienawidzisz? Obojętny?Warning: date(): Invalid date.timezone value 'Europe/Kyiv', we selected the timezone 'UTC' for now. in /var/www/agent_stack/data/www/doraprojects.net/template/agent.layouts/content.php on line 54
2017-05-23 11:55:07
alter sequence serial restart start with 0;
Ta funkcja jest nowa w Oracle 12c. jest ona , a nie zawarta w oficjalnej dokumentacji . Znalazłem go w skryptach generowanych przez pakiet Oracle DBMS_METADATA_DIFF .
WARNING: używałem tej funkcji kilka razy na systemach produkcyjnych i moim zdaniem dobrze jest używać tej komendy w skryptach ad-hoc. Ale możesz nie chcieć włączyć go do procedury jako część wniosku. Stworzyłem zapytanie serwisowe Oracle z pytaniem o to funkcja; to nie tylko błąd w dokumentacji, to nieobsługiwana funkcja. Możliwe, że komenda kiedyś zniknie, jak WM_CONCAT
. (Chociaż myślę, że to mało prawdopodobne - składnia Oracle rzadko znika, a to prosta funkcja używana wewnętrznie w co najmniej dwóch miejscach.)
Warning: date(): Invalid date.timezone value 'Europe/Kyiv', we selected the timezone 'UTC' for now. in /var/www/agent_stack/data/www/doraprojects.net/template/agent.layouts/content.php on line 54
2018-01-03 19:49:03
Następujący skrypt ustawia sekwencję na żądaną wartość:
Podano świeżo utworzoną sekwencję o nazwie PCS_PROJ_KEY_SEQ i tabeli PCS_PROJ:
BEGIN
DECLARE
PROJ_KEY_MAX NUMBER := 0;
PROJ_KEY_CURRVAL NUMBER := 0;
BEGIN
SELECT MAX (PROJ_KEY) INTO PROJ_KEY_MAX FROM PCS_PROJ;
EXECUTE IMMEDIATE 'ALTER SEQUENCE PCS_PROJ_KEY_SEQ INCREMENT BY ' || PROJ_KEY_MAX;
SELECT PCS_PROJ_KEY_SEQ.NEXTVAL INTO PROJ_KEY_CURRVAL FROM DUAL;
EXECUTE IMMEDIATE 'ALTER SEQUENCE PCS_PROJ_KEY_SEQ INCREMENT BY 1';
END;
END;
/
Warning: date(): Invalid date.timezone value 'Europe/Kyiv', we selected the timezone 'UTC' for now. in /var/www/agent_stack/data/www/doraprojects.net/template/agent.layouts/content.php on line 54
2012-04-08 14:18:58
Ta procedura składowana uruchamia ponownie moją sekwencję:
Create or Replace Procedure Reset_Sequence
is
SeqNbr Number;
begin
/* Reset Sequence 'seqXRef_RowID' to 0 */
Execute Immediate 'Select seqXRef.nextval from dual ' Into SeqNbr;
Execute Immediate 'Alter sequence seqXRef increment by - ' || TO_CHAR(SeqNbr) ;
Execute Immediate 'Select seqXRef.nextval from dual ' Into SeqNbr;
Execute Immediate 'Alter sequence seqXRef increment by 1';
END;
/
Warning: date(): Invalid date.timezone value 'Europe/Kyiv', we selected the timezone 'UTC' for now. in /var/www/agent_stack/data/www/doraprojects.net/template/agent.layouts/content.php on line 54
2012-04-08 14:16:21
Istnieje inny sposób resetowania sekwencji w Oracle: ustaw właściwości maxvalue
i cycle
. Gdy nextval
sekwencji trafi maxvalue
, Jeśli właściwość cycle
jest ustawiona, rozpocznie się ona ponownie od minvalue
sekwencji.
Zaletą tej metody w porównaniu do Ustawienia ujemnego increment by
jest to, że sekwencja może być nadal używana podczas uruchamiania procesu resetowania, zmniejszając ryzyko, że trzeba podjąć jakąś formę przerwy w resecie.
Wartość dla maxvalue
musi być większa niż bieżąca nextval
, więc poniższa procedura zawiera opcjonalny parametr pozwalający na utworzenie bufora w przypadku ponownego dostępu do sekwencji pomiędzy wybraniem nextval
w procedurze a ustawieniem właściwości cycle
.
create sequence s start with 1 increment by 1;
select s.nextval from dual
connect by level <= 20;
NEXTVAL
----------
1
...
20
create or replace procedure reset_sequence ( i_buffer in pls_integer default 0)
as
maxval pls_integer;
begin
maxval := s.nextval + greatest(i_buffer, 0); --ensure we don't go backwards!
execute immediate 'alter sequence s cycle minvalue 0 maxvalue ' || maxval;
maxval := s.nextval;
execute immediate 'alter sequence s nocycle maxvalue 99999999999999';
end;
/
show errors
exec reset_sequence;
select s.nextval from dual;
NEXTVAL
----------
1
Procedura w obecnym stanie pozwala na to, że inna sesja pobierze wartość 0, co może, ale nie musi być problemem dla Ciebie. Jeśli tak, zawsze możesz:
- Ustaw
minvalue 1
w pierwszej zmianie - Wyłącz drugi
nextval
aport - Przenieś instrukcję, aby ustawić właściwość
nocycle
do innej procedury, która zostanie uruchomiona w późniejszym terminie(zakładając, że chcesz to zrobić).
Warning: date(): Invalid date.timezone value 'Europe/Kyiv', we selected the timezone 'UTC' for now. in /var/www/agent_stack/data/www/doraprojects.net/template/agent.layouts/content.php on line 54
2013-02-10 17:09:03
1) Załóżmy, że tworzysz sekwencję jak pokazano poniżej:
CREATE SEQUENCE TESTSEQ
INCREMENT BY 1
MINVALUE 1
MAXVALUE 500
NOCACHE
NOCYCLE
NOORDER
2) Teraz pobierasz wartości z sekwencji. Powiedzmy, że pobrałem cztery razy, jak pokazano poniżej.
SELECT TESTSEQ.NEXTVAL FROM dual
SELECT TESTSEQ.NEXTVAL FROM dual
SELECT TESTSEQ.NEXTVAL FROM dual
SELECT TESTSEQ.NEXTVAL FROM dual
3) Po wykonaniu powyższych czterech poleceń wartość sekwencji wyniesie 4. Załóżmy, że ponownie zresetowałem wartość sekwencji na 1. Wykonaj następujące kroki. Wykonaj wszystkie kroki w tej samej kolejności, jak pokazano poniżej:
ALTER SEQUENCE TESTSEQ INCREMENT BY -3;
SELECT TESTSEQ.NEXTVAL FROM dual
ALTER SEQUENCE TESTSEQ INCREMENT BY 1;
SELECT TESTSEQ.NEXTVAL FROM dual
Warning: date(): Invalid date.timezone value 'Europe/Kyiv', we selected the timezone 'UTC' for now. in /var/www/agent_stack/data/www/doraprojects.net/template/agent.layouts/content.php on line 54
2011-02-14 17:30:31
Zmiana wartości przyrostu sekwencji, zwiększenie jej, a następnie zmiana jej z powrotem jest dość bezbolesna, plus masz dodatkową zaletę, że nie musisz ponownie ustanawiać wszystkich dotacji, tak jak byś upuścił / odtworzył sekwencję.
Warning: date(): Invalid date.timezone value 'Europe/Kyiv', we selected the timezone 'UTC' for now. in /var/www/agent_stack/data/www/doraprojects.net/template/agent.layouts/content.php on line 54
2012-04-08 14:15:39
Tworzę blok aby zresetować wszystkie moje sekwencje:
DECLARE
I_val number;
BEGIN
FOR US IN
(SELECT US.SEQUENCE_NAME FROM USER_SEQUENCES US)
LOOP
execute immediate 'select ' || US.SEQUENCE_NAME || '.nextval from dual' INTO l_val;
execute immediate 'alter sequence ' || US.SEQUENCE_NAME || ' increment by -' || l_val || ' minvalue 0';
execute immediate 'select ' || US.SEQUENCE_NAME || '.nextval from dual' INTO l_val;
execute immediate 'alter sequence ' || US.SEQUENCE_NAME || ' increment by 1 minvalue 0';
END LOOP;
END;
Warning: date(): Invalid date.timezone value 'Europe/Kyiv', we selected the timezone 'UTC' for now. in /var/www/agent_stack/data/www/doraprojects.net/template/agent.layouts/content.php on line 54
2015-06-04 19:08:46
Oto bardziej solidna procedura zmiany następnej wartości zwracanej przez sekwencję, plus dużo więcej.
- Po pierwsze chroni przed atakami SQL injection, ponieważ żaden z przekazywanych łańcuchów nie jest używany do bezpośredniego tworzenia dynamicznych poleceń SQL,
- drugi zapobiega ustawianiu wartości następnej sekwencji poza granicami wartości min lub max sekwencji.
next_value
będzie !=min_value
i pomiędzymin_value
amax_value
. - Po trzecie trzeba bieżące (lub proponowane)
increment_by
Ustawienie, jak również wszystkie inne ustawienia sekwencji uwzględniane podczas czyszczenia. - Po czwarte wszystkie parametry z wyjątkiem pierwszego są opcjonalne i jeśli nie podano, przyjmują bieżące ustawienie sekwencji jako domyślne. Jeśli nie podano opcjonalnych parametrów, nie są podejmowane żadne działania.
- na koniec, jeśli spróbujesz zmienić sekwencję, która nie istnieje (lub nie jest własnością bieżącego użytkownika), spowoduje to błąd
ORA-01403: no data found
.
Oto kod:
CREATE OR REPLACE PROCEDURE alter_sequence(
seq_name user_sequences.sequence_name%TYPE
, next_value user_sequences.last_number%TYPE := null
, increment_by user_sequences.increment_by%TYPE := null
, min_value user_sequences.min_value%TYPE := null
, max_value user_sequences.max_value%TYPE := null
, cycle_flag user_sequences.cycle_flag%TYPE := null
, cache_size user_sequences.cache_size%TYPE := null
, order_flag user_sequences.order_flag%TYPE := null)
AUTHID CURRENT_USER
AS
l_seq user_sequences%rowtype;
l_old_cache user_sequences.cache_size%TYPE;
l_next user_sequences.min_value%TYPE;
BEGIN
-- Get current sequence settings as defaults
SELECT * INTO l_seq FROM user_sequences WHERE sequence_name = seq_name;
-- Update target settings
l_old_cache := l_seq.cache_size;
l_seq.increment_by := nvl(increment_by, l_seq.increment_by);
l_seq.min_value := nvl(min_value, l_seq.min_value);
l_seq.max_value := nvl(max_value, l_seq.max_value);
l_seq.cycle_flag := nvl(cycle_flag, l_seq.cycle_flag);
l_seq.cache_size := nvl(cache_size, l_seq.cache_size);
l_seq.order_flag := nvl(order_flag, l_seq.order_flag);
IF next_value is NOT NULL THEN
-- Determine next value without exceeding limits
l_next := LEAST(GREATEST(next_value, l_seq.min_value+1),l_seq.max_value);
-- Grab the actual latest seq number
EXECUTE IMMEDIATE
'ALTER SEQUENCE '||l_seq.sequence_name
|| ' INCREMENT BY 1'
|| ' MINVALUE '||least(l_seq.min_value,l_seq.last_number-l_old_cache)
|| ' MAXVALUE '||greatest(l_seq.max_value,l_seq.last_number)
|| ' NOCACHE'
|| ' ORDER';
EXECUTE IMMEDIATE
'SELECT '||l_seq.sequence_name||'.NEXTVAL FROM DUAL'
INTO l_seq.last_number;
l_next := l_next-l_seq.last_number-1;
-- Reset the sequence number
IF l_next <> 0 THEN
EXECUTE IMMEDIATE
'ALTER SEQUENCE '||l_seq.sequence_name
|| ' INCREMENT BY '||l_next
|| ' MINVALUE '||least(l_seq.min_value,l_seq.last_number)
|| ' MAXVALUE '||greatest(l_seq.max_value,l_seq.last_number)
|| ' NOCACHE'
|| ' ORDER';
EXECUTE IMMEDIATE
'SELECT '||l_seq.sequence_name||'.NEXTVAL FROM DUAL'
INTO l_next;
END IF;
END IF;
-- Prepare Sequence for next use.
IF COALESCE( cycle_flag
, next_value
, increment_by
, min_value
, max_value
, cache_size
, order_flag) IS NOT NULL
THEN
EXECUTE IMMEDIATE
'ALTER SEQUENCE '||l_seq.sequence_name
|| ' INCREMENT BY '||l_seq.increment_by
|| ' MINVALUE '||l_seq.min_value
|| ' MAXVALUE '||l_seq.max_value
|| CASE l_seq.cycle_flag
WHEN 'Y' THEN ' CYCLE' ELSE ' NOCYCLE' END
|| CASE l_seq.cache_size
WHEN 0 THEN ' NOCACHE'
ELSE ' CACHE '||l_seq.cache_size END
|| CASE l_seq.order_flag
WHEN 'Y' THEN ' ORDER' ELSE ' NOORDER' END;
END IF;
END;
Warning: date(): Invalid date.timezone value 'Europe/Kyiv', we selected the timezone 'UTC' for now. in /var/www/agent_stack/data/www/doraprojects.net/template/agent.layouts/content.php on line 54
2015-08-14 19:32:49
W moim projekcie zdarzyło się kiedyś, że ktoś ręcznie wpisywał rekordy bez użycia sekwencji, dlatego muszę ręcznie resetować wartość sekwencji, dla której napisałem poniżej fragment kodu sql:
declare
max_db_value number(10,0);
cur_seq_value number(10,0);
counter number(10,0);
difference number(10,0);
dummy_number number(10);
begin
-- enter table name here
select max(id) into max_db_value from persons;
-- enter sequence name here
select last_number into cur_seq_value from user_sequences where sequence_name = 'SEQ_PERSONS';
difference := max_db_value - cur_seq_value;
for counter in 1..difference
loop
-- change sequence name here as well
select SEQ_PERSONS.nextval into dummy_number from dual;
end loop;
end;
Proszę zauważyć, że powyższy kod będzie działał, jeśli sekwencja jest opóźniona.
Warning: date(): Invalid date.timezone value 'Europe/Kyiv', we selected the timezone 'UTC' for now. in /var/www/agent_stack/data/www/doraprojects.net/template/agent.layouts/content.php on line 54
2015-09-29 05:25:27
Jezu, całe to programowanie tylko dla restartu indeksu... Może jestem idiotą, ale dla pre-oracle 12 (który ma funkcję restartu), co jest nie tak z simpel:
drop sequence blah;
create sequence blah
?
Warning: date(): Invalid date.timezone value 'Europe/Kyiv', we selected the timezone 'UTC' for now. in /var/www/agent_stack/data/www/doraprojects.net/template/agent.layouts/content.php on line 54
2017-04-25 15:08:49
Możesz użyć opcji cyklu, pokazanej poniżej:
CREATE SEQUENCE test_seq
MINVALUE 0
MAXVALUE 100
START WITH 0
INCREMENT BY 1
CYCLE;
W tym przypadku, gdy sekwencja osiągnie wartość MAXVALUE (100), zostanie ona zwrócona do wartości MINVALUE (0).
W przypadku sekwencji zmniejszonej, Sekwencja zostanie zwrócona do wartości maksymalnej.
Warning: date(): Invalid date.timezone value 'Europe/Kyiv', we selected the timezone 'UTC' for now. in /var/www/agent_stack/data/www/doraprojects.net/template/agent.layouts/content.php on line 54
2014-03-25 15:51:05
Oto jak sprawić, by wszystkie sekwencje auto-inkrementacji pasowały do rzeczywistych danych:
-
Utwórz procedurę wymuszającą następną wartość, jak już opisano w tym wątku:
CREATE OR REPLACE PROCEDURE Reset_Sequence( P_Seq_Name IN VARCHAR2, P_Val IN NUMBER DEFAULT 0) IS L_Current NUMBER := 0; L_Difference NUMBER := 0; L_Minvalue User_Sequences.Min_Value%Type := 0; BEGIN SELECT Min_Value INTO L_Minvalue FROM User_Sequences WHERE Sequence_Name = P_Seq_Name; EXECUTE Immediate 'select ' || P_Seq_Name || '.nextval from dual' INTO L_Current; IF P_Val < L_Minvalue THEN L_Difference := L_Minvalue - L_Current; ELSE L_Difference := P_Val - L_Current; END IF; IF L_Difference = 0 THEN RETURN; END IF; EXECUTE Immediate 'alter sequence ' || P_Seq_Name || ' increment by ' || L_Difference || ' minvalue ' || L_Minvalue; EXECUTE Immediate 'select ' || P_Seq_Name || '.nextval from dual' INTO L_Difference; EXECUTE Immediate 'alter sequence ' || P_Seq_Name || ' increment by 1 minvalue ' || L_Minvalue; END Reset_Sequence;
-
Utwórz inną procedurę, aby pogodzić wszystkie sekwencje z rzeczywistą treścią:
CREATE OR REPLACE PROCEDURE RESET_USER_SEQUENCES_TO_DATA IS STMT CLOB; BEGIN SELECT 'select ''BEGIN'' || chr(10) || x || chr(10) || ''END;'' FROM (select listagg(x, chr(10)) within group (order by null) x FROM (' || X || '))' INTO STMT FROM (SELECT LISTAGG(X, ' union ') WITHIN GROUP ( ORDER BY NULL) X FROM (SELECT CHR(10) || 'select ''Reset_Sequence(''''' || SEQ_NAME || ''''','' || coalesce(max(' || COL_NAME || '), 0) || '');'' x from ' || TABLE_NAME X FROM (SELECT TABLE_NAME, REGEXP_SUBSTR(WTEXT, 'NEW\.(\S*) IS NULL',1,1,'i',1) COL_NAME, REGEXP_SUBSTR(BTEXT, '(\.|\s)([a-z_]*)\.nextval',1,1,'i',2) SEQ_NAME FROM USER_TRIGGERS LEFT JOIN (SELECT NAME BNAME, TEXT BTEXT FROM USER_SOURCE WHERE TYPE = 'TRIGGER' AND UPPER(TEXT) LIKE '%NEXTVAL%' ) ON BNAME = TRIGGER_NAME LEFT JOIN (SELECT NAME WNAME, TEXT WTEXT FROM USER_SOURCE WHERE TYPE = 'TRIGGER' AND UPPER(TEXT) LIKE '%IS NULL%' ) ON WNAME = TRIGGER_NAME WHERE TRIGGER_TYPE = 'BEFORE EACH ROW' AND TRIGGERING_EVENT = 'INSERT' ) ) ) ; EXECUTE IMMEDIATE STMT INTO STMT; --dbms_output.put_line(stmt); EXECUTE IMMEDIATE STMT; END RESET_USER_SEQUENCES_TO_DATA;
Uwagi:
- procedura wyodrębnia nazwy z kodu wyzwalacza i nie zależy od konwencji nazewnictwa
- aby sprawdzić wygenerowany kod przed wykonaniem, Przełącz komentarze na last dwie linie
Warning: date(): Invalid date.timezone value 'Europe/Kyiv', we selected the timezone 'UTC' for now. in /var/www/agent_stack/data/www/doraprojects.net/template/agent.layouts/content.php on line 54
2017-06-23 06:45:39
Robię alternatywę, że użytkownik nie musi znać wartości, system pobiera i używa zmiennych do aktualizacji.
--Atualizando sequence da tabela SIGA_TRANSACAO, pois está desatualizada
DECLARE
actual_sequence_number INTEGER;
max_number_from_table INTEGER;
difference INTEGER;
BEGIN
SELECT [nome_da_sequence].nextval INTO actual_sequence_number FROM DUAL;
SELECT MAX([nome_da_coluna]) INTO max_number_from_table FROM [nome_da_tabela];
SELECT (max_number_from_table-actual_sequence_number) INTO difference FROM DUAL;
IF difference > 0 then
EXECUTE IMMEDIATE CONCAT('alter sequence [nome_da_sequence] increment by ', difference);
--aqui ele puxa o próximo valor usando o incremento necessário
SELECT [nome_da_sequence].nextval INTO actual_sequence_number from dual;
--aqui volta o incremento para 1, para que futuras inserções funcionem normalmente
EXECUTE IMMEDIATE 'ALTER SEQUENCE [nome_da_sequence] INCREMENT by 1';
DBMS_OUTPUT.put_line ('A sequence [nome_da_sequence] foi atualizada.');
ELSE
DBMS_OUTPUT.put_line ('A sequence [nome_da_sequence] NÃO foi atualizada, já estava OK!');
END IF;
END;
Warning: date(): Invalid date.timezone value 'Europe/Kyiv', we selected the timezone 'UTC' for now. in /var/www/agent_stack/data/www/doraprojects.net/template/agent.layouts/content.php on line 54
2017-09-13 10:26:19