Pobierz listę przekazywanych argumentów w Windows batch script (.bat)

%* wydaje się, że przechowuje wszystkie argumenty przekazane do skryptu.

%1 ... %n i %* przechowują argumenty, ale dostęp do nich może być trudny, ponieważ treść będzie interpretowana.
Dlatego nie można obsługiwać czegoś takiego za pomocą zwykłych instrukcji

myBatch.bat "&"^&

Każda linia zawiedzie, jako cmd.exe próbuje wykonać jeden z ampersandów (zawartość %1 to "&"&)

set var=%1
set "var=%1"
set var=%~1
set "var=%~1"

Ale istnieje obejście z plikiem tymczasowym

@echo off
SETLOCAL DisableDelayedExpansion

SETLOCAL
for %%a in (1) do (
    set "prompt=$_"
    echo on
    for %%b in (1) do rem * #%1#
    @echo off
) > param.txt
ENDLOCAL

for /F "delims=" %%L in (param.txt) do (
  set "param1=%%L"
)
SETLOCAL EnableDelayedExpansion
set "param1=!param1:*#=!"
set "param1=!param1:~0,-2!"
echo %%1 is '!param1!'

Sztuczka polega na włączeniu echo on i rozwinięciu %1 Po rem oświadczenie (działa również z %2 .. %*).
Ale aby móc przekierować wyjście echo on, potrzebujesz dwóch pętli FOR.

Dodatkowe znaki * # są używane do ochrony przed treściami takimi jak /? (pokazuje pomoc dla REM).
Lub karetka ^ na końcu linii może działać jako znak wielowierszowy.

FOR / F powinno działać z opóźnionym rozszerzeniem off, w przeciwnym razie zawartość z "!"zostałby zniszczony.
Po usunięciu dodatkowych znaków w param1 i masz to.

I aby używać param1 w bezpieczny sposób, włącz opóźnioną ekspansję.

Edit: jedna uwaga do %0

%0 zawiera polecenie używane do wywołania partii, zachowując również przypadek, jak w FoO.BaT
Ale po wywołaniu funkcji %0, a także w %~0 zawiera nazwę funkcji (lub lepiej łańcuch, który został użyty do wywołania funkcji).
Ale z %~f0 nadal możesz przypomnieć sobie nazwę pliku.

@echo off
echo main %0, %~0, %~f0
call :myLabel+xyz
exit /b

:MYlabel
echo func %0, %~0, %~f0
exit /b

Wyjście

main test.bat, test.bat, C:\temp\test.bat
func :myLabel+xyz, :myLabel+xyz, C:\temp\test.bat

Znalazłem to następnym razem, kiedy będziesz musiał sprawdzić te informacje. Zamiast otwierać przeglądarkę i wygooglować ją, możesz po prostu wpisać call /? W cmd i dostaniesz ją:

...

%* in a batch script refers to all the arguments (e.g. %1 %2 %3
    %4 %5 ...)

Substitution of batch parameters (%n) has been enhanced.  You can
now use the following optional syntax:

    %~1         - expands %1 removing any surrounding quotes (")
    %~f1        - expands %1 to a fully qualified path name
    %~d1        - expands %1 to a drive letter only
    %~p1        - expands %1 to a path only
    %~n1        - expands %1 to a file name only
    %~x1        - expands %1 to a file extension only
    %~s1        - expanded path contains short names only
    %~a1        - expands %1 to file attributes
    %~t1        - expands %1 to date/time of file
    %~z1        - expands %1 to size of file
    %~$PATH:1   - searches the directories listed in the PATH
                   environment variable and expands %1 to the fully
                   qualified name of the first one found.  If the
                   environment variable name is not defined or the
                   file is not found by the search, then this
                   modifier expands to the empty string

The modifiers can be combined to get compound results:

    %~dp1       - expands %1 to a drive letter and path only
    %~nx1       - expands %1 to a file name and extension only
    %~dp$PATH:1 - searches the directories listed in the PATH
                   environment variable for %1 and expands to the
                   drive letter and path of the first one found.
    %~ftza1     - expands %1 to a DIR like output line

In the above examples %1 and PATH can be replaced by other
valid values.  The %~ syntax is terminated by a valid argument
number.  The %~ modifiers may not be used with %*

Sposób, aby pobrać wszystkie args do skryptu jest tutaj:

@ECHO off
ECHO The %~nx0 script args are...
for %%I IN (%*) DO ECHO %%I
pause

Oto dość prosty sposób na pobranie args i ustawienie ich jako var env. W tym przykładzie będę się odnosił do nich jako do kluczy i wartości.

Zapisz poniższy przykład kodu jako " args.bat". Następnie wywołaj plik wsadowy zapisałeś z wiersza poleceń. przykład: arg.bat --x 90 -- y 120

Dostarczyłem kilka poleceń echo, które przeprowadzą cię przez proces. Ale wynikiem końcowym jest to, że --x będzie miał wartość 90, a --y będzie miał wartość 120(to znaczy, jeśli uruchomisz przykład zgodnie z podanymi powyżej; -)).

Możesz użyć instrukcji warunkowej "if defined", aby określić, czy chcesz uruchomić blok kodu. Więc powiedzmy run: "arg.bat --x hello-world" Mógłbym wtedy użyć polecenia "IF DEFINED --x echo %--x%" i wynik byłby "hello-world". Powinno to mieć większy sens, jeśli uruchomisz partię.

@setlocal enableextensions enabledelayedexpansion
@ECHO off
ECHO.
ECHO :::::::::::::::::::::::::: arg.bat example :::::::::::::::::::::::::::::::
ECHO :: By:      User2631477, 2013-07-29                                   ::
ECHO :: Version: 1.0                                                         ::
ECHO :: Purpose: Checks the args passed to the batch.                        ::
ECHO ::                                                                      ::
ECHO :: Start by gathering all the args with the %%* in a for loop.          ::
ECHO ::                                                                      ::
ECHO :: Now we use a 'for' loop to search for our keys which are identified  ::
ECHO :: by the text '--'. The function then sets the --arg ^= to the next    ::
ECHO :: arg. "CALL:Function_GetValue" ^<search for --^> ^<each arg^>         ::
ECHO ::                                                                      ::
ECHO ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::

ECHO.

ECHO ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
ECHO :: From the command line you could pass... arg.bat --x 90 --y 220       ::
ECHO ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
ECHO.
ECHO.Checking Args:"%*"

FOR %%a IN (%*) do (
    CALL:Function_GetValue "--","%%a" 
)

ECHO.
ECHO ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
ECHO :: Now lets check which args were set to variables...                   ::
ECHO ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
ECHO.
ECHO ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
ECHO :: For this we are using the CALL:Function_Show_Defined "--x,--y,--z"   ::
ECHO ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
ECHO.
CALL:Function_Show_Defined "--x,--y,--z"
endlocal
goto done

:Function_GetValue

REM First we use find string to locate and search for the text.
echo.%~2 | findstr /C:"%~1" 1>nul

REM Next we check the errorlevel return to see if it contains a key or a value
REM and set the appropriate action.

if not errorlevel 1 (
  SET KEY=%~2
) ELSE (
  SET VALUE=%~2
)
IF DEFINED VALUE (
    SET %KEY%=%~2
    ECHO.
    ECHO ::::::::::::::::::::::::: %~0 ::::::::::::::::::::::::::::::
    ECHO :: The KEY:'%KEY%' is now set to the VALUE:'%VALUE%'                     ::
    ECHO :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
    ECHO.
    ECHO %KEY%=%~2
    ECHO.
    REM It's important to clear the definitions for the key and value in order to
    REM search for the next key value set.
    SET KEY=
    SET VALUE=
)
GOTO:EOF

:Function_Show_Defined 
ECHO.
ECHO ::::::::::::::::::: %~0 ::::::::::::::::::::::::::::::::
ECHO :: Checks which args were defined i.e. %~2
ECHO :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
ECHO.
SET ARGS=%~1
for %%s in (%ARGS%) DO (
    ECHO.
    ECHO :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
    ECHO :: For the ARG: '%%s'                         
    IF DEFINED %%s (
        ECHO :: Defined as: '%%s=!%%s!'                                             
    ) else (
        ECHO :: Not Defined '%%s' and thus has no value.
    )
    ECHO :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
    ECHO.
)
goto:EOF

:done

Poniższy kod symuluje tablicę ('params') - pobiera parametry otrzymane przez skrypt i zapisuje je w zmiennych params_1.. params_n, Gdzie n=params_0=liczba elementów tablicy:

@echo off

rem Storing the program parameters into the array 'params':
rem Delayed expansion is left disabled in order not to interpret "!" in program parameters' values;
rem however, if a parameter is not quoted, special characters in it (like "^", "&", "|") get interpreted at program launch
set /a count=0
:repeat
    set /a count+=1
    set "params_%count%=%~1"
    shift
    if defined params_%count% (
        goto :repeat
    ) else (
        set /a count-=1
    )    
set /a params_0=count

rem Printing the program parameters stored in the array 'params':
rem After the variables params_1 .. params_n are set with the program parameters' values, delayed expansion can
rem be enabled and "!" are not interpreted in the variables params_1 .. params_n values
setlocal enabledelayedexpansion
    for /l %%i in (1,1,!params_0!) do (
        echo params_%%i: "!params_%%i!"
    )
endlocal

pause
goto :eof

@echo off
:start

:: Insert your code here
echo.%%1 is now:%~1
:: End insert your code here

if "%~2" NEQ "" (
    shift
    goto :start
)

Wiele powyższych informacji doprowadziło mnie do dalszych badań i ostatecznie mojej odpowiedzi, więc chciałem przyczynić się do tego, co zrobiłem w nadziei, że pomoże to komuś innemu: {]}

• Chciałem również przekazać zróżnicowaną liczbę zmiennych do pliku wsadowego, aby mogły być przetwarzane w pliku.

• Nie przeszkadzało mi przekazywanie ich do pliku wsadowego za pomocą cudzysłowów

• Chciałbym, aby były przetwarzane podobnie jak poniżej - ale za pomocą pętli zamiast pisania out manually:

Więc chciałem wykonać to:

prog_ZipDeleteFiles.bat "_appPath=C:\Services\Logs\PCAP" "_appFile=PCAP*.?"

I za pomocą magii pętli for wykonaj to w pliku wsadowym:

set "_appPath=C:\Services\Logs\PCAP"
set "_appFile=PCAP*.?"

Problem, który miałem polega na tym, że wszystkie moje próby użycia pętli for nie działały. Poniższy przykład:

for /f "tokens* delims= " in %%A (%*) DO (
   set %%A
)

Zrobiłby:

set "_appPath=C:\Services\Logs\PCAP"

A nie:

set "_appPath=C:\Services\Logs\PCAP"
set "_appFile=PCAP*.?"

Nawet po ustawieniu

SETLOCAL EnableDelayedExpansion

Powodem było to, że pętla for odczytała całą linię I przypisała mój drugi parametr do % % B podczas pierwszej iteracji pętla. Ponieważ % * reprezentuje wszystkie argumenty, do przetworzenia jest tylko jedna linia-Ergo dzieje się tylko jedno przejście pętli for. Okazuje się, że to z założenia, a moja logika się myliła.

Przestałem więc używać pętli for I uprościłem to, co próbowałem zrobić, używając if, shift i instrukcji goto. Zgadzam się, że to trochę hack, ale jest bardziej dopasowany do moich potrzeb. Mogę przejrzeć wszystkie argumenty, a następnie użyć instrukcji if, aby opuścić pętlę po przetworzeniu ich wszystkie.

Zwycięska wypowiedź za to, co chciałem osiągnąć:

echo on
:processArguments
:: Process all arguments in the order received
if defined %1 then (
    set %1
    shift
    goto:processArguments
) ELSE (
    echo off 
)

UPDATE-zamiast tego musiałem zmodyfikować poniżej, ujawniałem wszystkie zmienne środowiskowe, próbując odwołać się do %1 i używając shift w ten sposób:

echo on
shift
:processArguments
:: Process all arguments in the order received
if defined %0 then (
    set %0
    shift
    goto:processArguments
) ELSE (
    echo off 
)

Jeśli masz parametry w cudzysłowach, które zawierają spacje, %* nie będzie działać poprawnie. Najlepszym rozwiązaniem, jakie znalazłem, jest posiadanie pętli, która łączy wszystkie argumenty: https://serverfault.com/a/22541

set args=%1
shift
:start
if [%1] == [] goto done
set args=%args% %1
shift
goto start

:done
(use %args% here)

Wersja Windows (wymaga jednak socat)

C:\Program Files (x86)\Git\bin>type gitproxy.cmd
socat STDIO PROXY:proxy.mycompany.de:%1:%2,proxyport=3128

Ustawienie:

C:\Users\exhau\AppData\Roaming\npm>git config --global core.gitproxy gitproxy.cmd

Możesz użyć %1, %2 etc, aby uzyskać dostęp do argumentów linii poleceń. Nie sądzę, że istnieje zmienna, która przechowuje całą listę. Możesz być w stanie napisać prostą pętlę, która określa, ile argumentów zostało przekazanych.

EDIT: widocznie jest :)

Dla kogoś, kto potrzebuje backslasha z basepath

set source=%~dp0
::Remove the trailing backslash from source
IF %source:~-1%==\ SET source=%source:~0,-1%
echo %source%