Aktualizacja Sierpień 2014

Poniższe rozwiązanie starsze zostało poprawione, aby działało w ostatnich wersjach (9 i 10).

W tym samym czasie jednak wprowadzenie PlotTheme funkcjonalność sprawia, że moje rozwiązanie jest w dużej mierze akademickie, ponieważ motywy fabuły są zaprojektowane tak, aby łączyć się w ten sam sposób. Jeśli żaden istniejący motyw nie ma pożądanego stylu, możesz utworzyć własny.

Ten przykład pokazuje ustawienie nowych domyślnych kolorów wykresu, a także niestandardowe grubość i te poprawnie łączące się z dyrektywami dashing w PlotStyle:

System`PlotThemeDump`resolvePlotTheme["Thick5", "Plot"] := 
 Themes`SetWeight[{"DefaultThickness" -> {AbsoluteThickness[5]}}, 
  System`PlotThemeDump`$ComponentWeight]

SetOptions[Plot, PlotTheme -> {"DarkColor", "Thick5"}];

fns = Table[x^n, {n, 0, 5}];
dash = Table[AbsoluteDashing[i], {i, 1, 6}];

Plot[fns, {x, -1, 1}, PlotStyle -> dash]

Starsze Rozwiązanie

Poniższe zaktualizowane rozwiązanie jest oparte na istniejących rozwiązaniach Janusa i belisariusa ze znacznym rozszerzeniem i ulepszeniem.

Funkcje pomocnicze

ClearAll[toDirective, styleJoin]

toDirective[{ps__} | ps__] := 
  Flatten[Directive @@ Flatten[{#}]] & /@ {ps}

styleJoin[style_, base_] :=
  Module[{ps, n},
    ps = toDirective /@ {PlotStyle /. Options[base], style};
    ps = ps /. Automatic :> Sequence[];
    n = LCM @@ Length /@ ps;
    MapThread[Join, PadRight[#, n, #] & /@ ps]
  ]

Główna funkcja

pp to lista funkcji wykresu, na które chcesz wpłynąć.

sh jest potrzebne do obsługi działek przelotowych jak LogPlot, LogLinearPlot, DateListLogPlot, itd.

pp = {Plot, ListPlot, ParametricPlot, ParametricPlot3D};

Unprotect /@ pp;

(#[a__, b : OptionsPattern[]] :=
   Block[{$alsoPS = True, sh},
     sh = Cases[{b}, ("MessagesHead" -> hd_) :> hd, {-2}, 1] /. {{z_} :> z, {} -> #};
     With[{new = styleJoin[OptionValue[PlotStyle], sh]}, #[a, PlotStyle -> new, b]]
   ] /; ! TrueQ[$alsoPS];
 DownValues[#] = RotateRight[DownValues@#]; (* fix for versions 9 and 10 *)
) & /@ pp;

Użycie

Teraz różne typy wykresu mogą być indywidualnie stylizowane w następujący sposób:

SetOptions[Plot, PlotStyle -> ColorData[3, "ColorList"]];

Lub w grupach (tutaj używając pp zdefiniowanych powyżej):

SetOptions[pp, PlotStyle -> ColorData[3, "ColorList"]];

Przykłady

PlotStyle opcje są następnie automatycznie dodawane:

fns = Table[x^n, {n, 0, 5}];
dash = Table[AbsoluteDashing[i], {i, 1, 6}];

Plot[fns, {x, -1, 1}, PlotStyle -> dash]

Plot[...] i Plot[..., PlotStyle -> Automatic] są spójne:

Plot[fns, {x, -1, 1}]
Plot[fns, {x, -1, 1}, PlotStyle -> Automatic]

Przelotowe działki (te, które wywołują Plot, ListPlot lub ParametricPlot) można nadać własny styl:

SetOptions[LogPlot, PlotStyle -> ColorData[2, "ColorList"]];

LogPlot[{Tanh[x], Erf[x]}, {x, 1, 5}]
LogPlot[{Tanh[x], Erf[x]}, {x, 1, 5}, PlotStyle -> {{Dashed, Thick}}]

PlotStyle obsługę można rozszerzyć na różne typy wykresu .

Dodałem ParametricPlot3D powyżej jako przykład:

fns = {1.16^v Cos[v](1 + Cos[u]), -1.16^v Sin[v](1 + Cos[u]), -2 1.16^v (1 + Sin[u])};

ParametricPlot3D[fns, {u, 0, 2 Pi}, {v, -15, 6},
  Mesh -> None, PlotStyle -> Opacity[0.6], PlotRange -> All, PlotPoints -> 25]

Uwaga Wdrożeniowa

W obecnym stanie zresetowanie SetOptions[..., PlotStyle -> Automatic] przywróci kolory do oryginalnych wartości domyślnych. Jeśli takie zachowanie jest niepożądane, kod można zmodyfikować, aby nadać inny domyślny kolor, w sposób funkcji also Janusa, na której wyraźnie opiera się moja styleJoin.