Prawidłowa obsługa błędów w VBA (Excel)

Masz jedną naprawdę cudowną odpowiedź od ray023, ale twój komentarz, że to prawdopodobnie przesada, jest trafny. Dla wersji "lżejszej"....

Blok 1 to, IMHO, zła praktyka. Jak już zauważył osknows, mieszanie obsługi błędów z kodem normalnej ścieżki nie jest dobre. Po pierwsze, Jeśli nowy błąd zostanie wyrzucony podczas działania warunku błędu, to Nie będzie można go obsłużyć (chyba że wywołujesz z procedury, która również ma błąd handler, gdzie wykonanie będzie "bąbelkowe").

Blok 2 wygląda jak imitacja bloku Try/Catch. Powinno być dobrze, ale to nie jest sposób VBA. blok 3 jest odmianą bloku 2.

Block 4 to wersja VBA. Ja bym zdecydowanie doradzał używanie go, czy coś podobnego, bo tego oczekuje każdy inny programista VBA dziedziczący kod. Pozwolę sobie jednak przedstawić małe rozszerzenie:

Private Sub DoSomething()
On Error GoTo ErrHandler

'Dim as required

'functional code that might throw errors

ExitSub:
    'any always-execute (cleanup?) code goes here -- analagous to a Finally block.
    'don't forget to do this -- you don't want to fall into error handling when there's no error
    Exit Sub

ErrHandler:
    'can Select Case on Err.Number if there are any you want to handle specially

    'display to user
    MsgBox "Something's wrong: " & vbCrLf & Err.Description

    'or use a central DisplayErr routine, written Public in a Module
    DisplayErr Err.Number, Err.Description

    Resume ExitSub
    Resume
End Sub

Zauważ, że drugi Resume. Jest to sztuczka, której się ostatnio nauczyłem: Nigdy nie będzie wykonywana w normalnym przetwarzaniu, ponieważ instrukcja Resume <label> wyśle wykonanie gdzie indziej. Może to być darem niebios dla debugowania. Gdy pojawi się powiadomienie o błędzie, wybierz Debug (lub naciśnij CTL-Break, a następnie wybierz Debug, gdy pojawi się komunikat" wykonanie zostało przerwane"). Następną (podświetloną) instrukcją będzie MsgBox lub następująca instrukcja. Użyj "Set Next Statement "(Ctl-F9), aby podświetlić nagie Resume, a następnie naciśnij F8. To pokaże ci dokładnie gdzie został wyrzucony błąd.

Jeśli chodzi o Twój sprzeciw wobec tego formatu "skakanie", a) tego oczekują Programiści VBA, jak wspomniano wcześniej, & B) Twoje procedury powinny być wystarczająco krótkie, aby nie było daleko do skoku.

Dwa główne cele obsługi błędów:

1. błędy pułapki, które możesz przewidzieć, ale nie może kontrolować użytkownika od zrobienia (np. zapisanie pliku do Pendrive gdy Pendrive został usunięty)
2. W przypadku nieprzewidzianych błędów, przedstawiamy użytkownikowi formularz które informuje ich o problemie jest. W ten sposób mogą przekazać wiadomość do ciebie, a być może będziesz w stanie aby dać im pracę wokół, podczas gdy ty popracuj nad naprawą.

Przede wszystkim Utwórz formularz błędu do wyświetlenia w przypadku wystąpienia nieoczekiwanego błędu.

Może wyglądać tak (FYI: mój nazywa się frmErrors):

Zwróć uwagę na następujące etykiety:

• lblHeadline
• lblSource
• lblProblem
• lblResponse

Również standardowe przyciski poleceń:

• Ignoruj
• Retry
• Anuluj

Nie ma nic spektakularnego w kodzie dla tej formy:

Option Explicit

Private Sub cmdCancel_Click()
  Me.Tag = CMD_CANCEL
  Me.Hide
End Sub

Private Sub cmdIgnore_Click()
  Me.Tag = CMD_IGNORE
  Me.Hide
End Sub

Private Sub cmdRetry_Click()
  Me.Tag = CMD_RETRY
  Me.Hide
End Sub

Private Sub UserForm_Initialize()
  Me.lblErrorTitle.Caption = "Custom Error Title Caption String"
End Sub

Private Sub UserForm_QueryClose(Cancel As Integer, CloseMode As Integer)
  'Prevent user from closing with the Close box in the title bar.
    If CloseMode <> 1 Then
      cmdCancel_Click
    End If
End Sub

W zasadzie, chcesz aby wiedzieć, który przycisk użytkownik nacisnął po zamknięciu formularza.

Następnie utwórz moduł obsługi błędów, który będzie używany w całej aplikacji VBA:

'****************************************************************
'    MODULE: ErrorHandler
'
'   PURPOSE: A VBA Error Handling routine to handle
'             any unexpected errors
'
'     Date:    Name:           Description:
'''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
'03/22/2010    Ray      Initial Creation
'****************************************************************
Option Explicit

Global Const CMD_RETRY = 0
Global Const CMD_IGNORE = 1
Global Const CMD_CANCEL = 2
Global Const CMD_CONTINUE = 3

Type ErrorType
    iErrNum As Long
    sHeadline As String
    sProblemMsg As String
    sResponseMsg As String
    sErrorSource As String
    sErrorDescription As String
    iBtnCap(3) As Integer
    iBitmap As Integer
End Type

Global gEStruc As ErrorType
Sub EmptyErrStruc_S(utEStruc As ErrorType)
  Dim i As Integer

  utEStruc.iErrNum = 0
  utEStruc.sHeadline = ""
  utEStruc.sProblemMsg = ""
  utEStruc.sResponseMsg = ""
  utEStruc.sErrorSource = ""
  For i = 0 To 2
    utEStruc.iBtnCap(i) = -1
  Next
  utEStruc.iBitmap = 1

End Sub
Function FillErrorStruct_F(EStruc As ErrorType) As Boolean
  'Must save error text before starting new error handler
  'in case we need it later
  EStruc.sProblemMsg = Error(EStruc.iErrNum)
  On Error GoTo vbDefaultFill

  EStruc.sHeadline = "Error " & Format$(EStruc.iErrNum)
  EStruc.sProblemMsg = EStruc.sErrorDescription
  EStruc.sErrorSource = EStruc.sErrorSource
  EStruc.sResponseMsg = "Contact the Company and tell them you received Error # " & Str$(EStruc.iErrNum) & ". You should write down the program function you were using, the record you were working with, and what you were doing."

   Select Case EStruc.iErrNum
       'Case Error number here
       'not sure what numeric errors user will ecounter, but can be implemented here
       'e.g.
       'EStruc.sHeadline = "Error 3265"
       'EStruc.sResponseMsg = "Contact tech support. Tell them what you were doing in the program."

     Case Else

       EStruc.sHeadline = "Error " & Format$(EStruc.iErrNum) & ": " & EStruc.sErrorDescription
       EStruc.sProblemMsg = EStruc.sErrorDescription

   End Select

   GoTo FillStrucEnd

vbDefaultFill:

  'Error Not on file
  EStruc.sHeadline = "Error " & Format$(EStruc.iErrNum) & ": Contact Tech Support"
  EStruc.sResponseMsg = "Contact the Company and tell them you received Error # " & Str$(EStruc.iErrNum)
FillStrucEnd:

  Exit Function

End Function
Function iErrorHandler_F(utEStruc As ErrorType) As Integer
  Static sCaption(3) As String
  Dim i As Integer
  Dim iMCursor As Integer

  Beep

  'Setup static array
  If Len(sCaption(0)) < 1 Then
    sCaption(CMD_IGNORE) = "&Ignore"
    sCaption(CMD_RETRY) = "&Retry"
    sCaption(CMD_CANCEL) = "&Cancel"
    sCaption(CMD_CONTINUE) = "Continue"
  End If

  Load frmErrors

  'Did caller pass error info?  If not fill struc with the needed info
  If Len(utEStruc.sHeadline) < 1 Then
    i = FillErrorStruct_F(utEStruc)
  End If

  frmErrors!lblHeadline.Caption = utEStruc.sHeadline
  frmErrors!lblProblem.Caption = utEStruc.sProblemMsg
  frmErrors!lblSource.Caption = utEStruc.sErrorSource
  frmErrors!lblResponse.Caption = utEStruc.sResponseMsg

  frmErrors.Show
  iErrorHandler_F = frmErrors.Tag   ' Save user response
  Unload frmErrors                  ' Unload and release form

  EmptyErrStruc_S utEStruc          ' Release memory

End Function

Możesz mieć błędy, które będą niestandardowe tylko dla Twojej aplikacji. Zazwyczaj jest to krótka lista błędów, które dotyczą tylko twojej aplikacji. Jeśli nie masz jeszcze modułu stałych, Utwórz taki, który będzie zawierał liczbę błędów niestandardowych. (Uwaga: Office '97 nie obsługuje enum.). ENUM powinno wyglądać coś takiego:

Public Enum CustomErrorName
  MaskedFilterNotSupported
  InvalidMonthNumber
End Enum

Stwórz moduł, który wyrzuci Twoje niestandardowe błędy.

'********************************************************************************************************************************
'    MODULE: CustomErrorList
'
'   PURPOSE: For trapping custom errors applicable to this application
'
'INSTRUCTIONS:  To use this module to create your own custom error:
'               1.  Add the Name of the Error to the CustomErrorName Enum
'               2.  Add a Case Statement to the raiseCustomError Sub
'               3.  Call the raiseCustomError Sub in the routine you may see the custom error
'               4.  Make sure the routine you call the raiseCustomError has error handling in it
'
'
'     Date:    Name:           Description:
'''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
'03/26/2010    Ray       Initial Creation
'********************************************************************************************************************************
Option Explicit
Const MICROSOFT_OFFSET = 512 'Microsoft reserves error values between vbObjectError and vbObjectError + 512
'************************************************************************************************
'  FUNCTION:  raiseCustomError
'
'   PURPOSE:  Raises a custom error based on the information passed
'
'PARAMETERS:  customError - An integer of type CustomErrorName Enum that defines the custom error
'             errorSource - The place the error came from
'
'   Returns:  The ASCII vaule that should be used for the Keypress
'
'     Date:    Name:           Description:
'''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
'03/26/2010    Ray       Initial Creation
'************************************************************************************************
Public Sub raiseCustomError(customError As Integer, Optional errorSource As String = "")
  Dim errorLong As Long
  Dim errorDescription As String

  errorLong = vbObjectError + MICROSOFT_OFFSET + customError

  Select Case customError

    Case CustomErrorName.MaskedFilterNotSupported
      errorDescription = "The mask filter passed is not supported"

    Case CustomErrorName.InvalidMonthNumber
      errorDescription = "Invalid Month Number Passed"

    Case Else
      errorDescription = "The custom error raised is unknown."

  End Select

  Err.Raise errorLong, errorSource, errorDescription

End Sub

Jesteś teraz dobrze przygotowany do pułapki błędów w swoim programie. SUB (lub funkcja), powinien wyglądać mniej więcej tak:

Public Sub MySub(monthNumber as Integer)
  On Error GoTo eh  

  Dim sheetWorkSheet As Worksheet

  'Run Some code here

  '************************************************
  '*   OPTIONAL BLOCK 1:  Look for a specific error
  '************************************************
  'Temporarily Turn off Error Handling so that you can check for specific error
  On Error Resume Next
  'Do some code where you might expect an error.  Example below:
  Const ERR_SHEET_NOT_FOUND = 9 'This error number is actually subscript out of range, but for this example means the worksheet was not found

  Set sheetWorkSheet = Sheets("January")

  'Now see if the expected error exists

  If Err.Number = ERR_SHEET_NOT_FOUND Then
    MsgBox "Hey!  The January worksheet is missing.  You need to recreate it."
    Exit Sub
  ElseIf Err.Number <> 0 Then
    'Uh oh...there was an error we did not expect so just run basic error handling 
    GoTo eh
  End If

  'Finished with predictable errors, turn basic error handling back on:
  On Error GoTo eh

  '**********************************************************************************
  '*   End of OPTIONAL BLOCK 1
  '**********************************************************************************

  '**********************************************************************************
  '*   OPTIONAL BLOCK 2:  Raise (a.k.a. "Throw") a Custom Error if applicable
  '**********************************************************************************
  If not (monthNumber >=1 and monthnumber <=12) then
    raiseCustomError CustomErrorName.InvalidMonthNumber, "My Sub"
  end if
  '**********************************************************************************
  '*   End of OPTIONAL BLOCK 2
  '**********************************************************************************

  'Rest of code in your sub

  goto sub_exit

eh:
  gEStruc.iErrNum = Err.Number
  gEStruc.sErrorDescription = Err.Description
  gEStruc.sErrorSource = Err.Source
  m_rc = iErrorHandler_F(gEStruc)

  If m_rc = CMD_RETRY Then
    Resume
  End If

sub_exit:
  'Any final processing you want to do.
  'Be careful with what you put here because if it errors out, the error rolls up.  This can be difficult to debug; especially if calling routine has no error handling.

  Exit Sub 'I was told a long time ago (10+ years) that exit sub was better than end sub...I can't tell you why, so you may not want to put in this line of code.  It's habit I can't break :P
End Sub

Kopiowanie / wklejanie powyższego kodu może nie działać bezpośrednio z bramy, ale zdecydowanie powinno dać ci gist.

BTW, jeśli kiedykolwiek potrzebujesz mnie do zrobienia logo Twojej firmy, zajrzyj do mnie http://www.MySuperCrappyLogoLabels99.com

Trzymam rzeczy proste:
Na poziomie modułu definiuję dwie zmienne i ustawiam jedną na nazwę samego modułu.

    Private Const ThisModuleName            As String = "mod_Custom_Functions"
    Public sLocalErrorMsg                   As String

W każdej Pod / funkcji modułu definiuję zmienną lokalną

    Dim ThisRoutineName                     As String

Ustawiam this Routinename na nazwę sub lub funkcji

' Housekeeping
    On Error Goto ERR_RTN
    ThisRoutineName = "CopyWorksheet"

Następnie wysyłam wszystkie błędy do ERR_RTN: kiedy występują, ale najpierw ustawiam sLocalErrorMsg, aby określić, czym jest błąd i podać pewne informacje o debugowaniu.

    If Len(Trim(FromWorksheetName)) < 1 Then
        sLocalErrorMsg = "Parameter 'FromWorksheetName' Is Missing."
        GoTo ERR_RTN
    End If

Na dole każdego sub / function, kieruję przepływ logiczny w następujący sposób

    '
    ' The "normal" logic goes here for what the routine does
    '
    GoTo EXIT_RTN

    ERR_RTN:

        On Error Resume Next

    ' Call error handler if we went this far.
        ErrorHandler ThisModuleName, ThisRoutineName, sLocalErrorMsg, Err.Description, Err.Number, False

    EXIT_RTN:

        On Error Resume Next
     '
     ' Some closing logic
     '
    End If

Następnie mam oddzielny moduł, który umieszczam we wszystkich projektach o nazwie "mod_Error_Handler".

    '
    '''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
    ' Subroutine Name:     ErrorHandler                                                     '
    '                                                                                       '
    ' Description:                                                                          '
    '   This module will handle the common error alerts.                                    '
    '                                                                                       '
    ' Inputs:                                                                               '
    '   ModuleName                String    'The name of the module error is in.            '
    '   RoutineName               String    'The name of the routine error in in.           '
    '   LocalErrorMsg             String    'A local message to assist with troubleshooting.'
    '   ERRDescription            String    'The Windows Error Description.                 '
    '   ERRCode                   Long      'The Windows Error Code.                        '
    '   Terminate                 Boolean   'End program if error encountered?              '
    '                                                                                       '
    ' Revision History:                                                                     '
    ' Date (YYYYMMDD) Author                Change                                          '
    ' =============== ===================== =============================================== '
    ' 20140529        XXXXX X. XXXXX        Original                                        '
    '                                                                                       '
    '''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
    '
    Public Sub ErrorHandler(ModuleName As String, RoutineName As String, LocalErrorMsg As String, ERRDescription As String, ERRCode As Long, Terminate As Boolean)
        Dim sBuildErrorMsg                 As String

    ' Build Error Message To Display
        sBuildErrorMsg = "Error Information:" & vbCrLf & vbCrLf

        If Len(Trim(ModuleName)) < 1 Then
            ModuleName = "Unknown"
        End If

        If Len(Trim(RoutineName)) < 1 Then
           RoutineName = "Unknown"
        End If

        sBuildErrorMsg = sBuildErrorMsg & "Module Name:        " & ModuleName & vbCrLf & vbCrLf
        sBuildErrorMsg = sBuildErrorMsg & "Routine Name:       " & RoutineName & vbCrLf & vbCrLf

        If Len(Trim(LocalErrorMsg)) > 0 Then
            sBuildErrorMsg = sBuildErrorMsg & "Local Error Msg:    " & LocalErrorMsg & vbCrLf & vbCrLf
        End If

        If Len(Trim(ERRDescription)) > 0 Then
            sBuildErrorMsg = sBuildErrorMsg & "Program Error Msg:  " & ERRDescription & vbCrLf & vbCrLf
            If IsNumeric(ERRCode) Then
                sBuildErrorMsg = sBuildErrorMsg & "Program Error Code: " & Trim(Str(ERRCode)) & vbCrLf & vbCrLf
            End If
        End If

        MsgBox sBuildErrorMsg, vbOKOnly + vbExclamation, "Error Detected!"

        If Terminate Then
            End
        End If

    End Sub

Rezultatem końcowym jest wyskakujący komunikat o błędzie, który mówi mi, jaki moduł, jaki soubroutine i jaki konkretnie był komunikat o błędzie. Ponadto wstawi również komunikat o błędzie i Kod systemu Windows.

Blok 2 nie działa, ponieważ nie resetuje obsługi błędów potencjalnie powodując nieskończoną pętlę. Aby Obsługa błędów działała poprawnie w VBA, potrzebujesz instrukcji Resume, aby wyczyścić obsługę błędów. Resume ponownie aktywuje również poprzedni program obsługi błędów. Blok 2 nie powiedzie się, ponieważ nowy błąd powróci do poprzedniego programu obsługi błędów, powodując nieskończoną pętlę.

Blok 3 nie powiedzie się, ponieważ nie ma Resume instrukcji, więc każda próba obsługi błędów po tym będzie porażka.

Każdy program obsługi błędów musi zostać zakończony zakończeniem procedury lub instrukcji Resume. Routing normalnego wykonywania wokół obsługi błędów jest mylące. Dlatego narzędzia do obsługi błędów są zwykle na dole.

Ale oto inny sposób radzenia sobie z błędem w VBA. Obsługuje błąd inline jak Try / Catch in VB.net jest kilka pułapek, ale odpowiednio zarządzane działa całkiem ładnie.

Sub InLineErrorHandling()

    'code without error handling

BeginTry1:

    'activate inline error handler
    On Error GoTo ErrHandler1

        'code block that may result in an error
        Dim a As String: a = "Abc"
        Dim c As Integer: c = a 'type mismatch

ErrHandler1:

    'handle the error
    If Err.Number <> 0 Then

        'the error handler has deactivated the previous error handler

        MsgBox (Err.Description)

        'Resume (or exit procedure) is the only way to get out of an error handling block
        'otherwise the following On Error statements will have no effect
        'CAUTION: it also reactivates the previous error handler
        Resume EndTry1
    End If

EndTry1:
    'CAUTION: since the Resume statement reactivates the previous error handler
    'you must ALWAYS use an On Error GoTo statement here
    'because another error here would cause an endless loop
    'use On Error GoTo 0 or On Error GoTo <Label>
    On Error GoTo 0

    'more code with or without error handling

End Sub

Źródła:

• http://www.cpearson.com/excel/errorhandling.htm
• http://msdn.microsoft.com/en-us/library/bb258159.aspx

Kluczem do wykonania tej pracy jest użycie Resume instrukcji natychmiast po niej następującej innej On Error instrukcji. {[1] } znajduje się w programie obsługi błędów i przekierowuje kod na etykietę EndTry1. Aby uniknąć problemów, należy natychmiast ustawić inną instrukcję On Error jako poprzedni program obsługi błędów będzie "wznowić". Oznacza to, że będzie aktywny i gotowy do obsługi innego błędu. Może to spowodować powtórzenie się błędu i wejście w nieskończoną pętlę.

Aby uniknąć ponownego użycia poprzedniego programu obsługi błędów, musisz ustawić On Error na nowy program obsługi błędów lub po prostu użyć On Error Goto 0, aby anulować wszystkie operacje obsługi błędów.