128 bit integer na cuda?

Aby uzyskać najlepszą wydajność, warto odwzorować 128-bitowy typ na odpowiednim typie wektorowym CUDA, takim jak uint4, i zaimplementować funkcjonalność za pomocą wbudowanego montażu PTX. Dodatek wyglądałby mniej więcej tak:

typedef uint4 my_uint128_t;
__device__ my_uint128_t add_uint128 (my_uint128_t addend, my_uint128_t augend)
{
    my_uint128_t res;
    asm ("add.cc.u32      %0, %4, %8;\n\t"
         "addc.cc.u32     %1, %5, %9;\n\t"
         "addc.cc.u32     %2, %6, %10;\n\t"
         "addc.u32        %3, %7, %11;\n\t"
         : "=r"(res.x), "=r"(res.y), "=r"(res.z), "=r"(res.w)
         : "r"(addend.x), "r"(addend.y), "r"(addend.z), "r"(addend.w),
           "r"(augend.x), "r"(augend.y), "r"(augend.z), "r"(augend.w));
    return res;
}

Mnożenie może być podobnie skonstruowane za pomocą wbudowanego montażu PTX, dzieląc 128-bitowe liczby na 32-bitowe kawałki, obliczając 64-bitowe produkty częściowe i dodając je odpowiednio. Oczywiście wymaga to trochę pracy. Można dostać rozsądna wydajność na poziomie C poprzez podzielenie liczby na 64-bitowe kawałki i użycie _ _ umul64hi () w połączeniu ze zwykłym 64-bitowym mnożeniem i pewnymi dodatkami. Wynikałoby to z:

__device__ my_uint128_t mul_uint128 (my_uint128_t multiplicand, 
                                     my_uint128_t multiplier)
{
    my_uint128_t res;
    unsigned long long ahi, alo, bhi, blo, phi, plo;
    alo = ((unsigned long long)multiplicand.y << 32) | multiplicand.x;
    ahi = ((unsigned long long)multiplicand.w << 32) | multiplicand.z;
    blo = ((unsigned long long)multiplier.y << 32) | multiplier.x;
    bhi = ((unsigned long long)multiplier.w << 32) | multiplier.z;
    plo = alo * blo;
    phi = __umul64hi (alo, blo) + alo * bhi + ahi * blo;
    res.x = (unsigned int)(plo & 0xffffffff);
    res.y = (unsigned int)(plo >> 32);
    res.z = (unsigned int)(phi & 0xffffffff);
    res.w = (unsigned int)(phi >> 32);
    return res;
}

Poniżej znajduje się Wersja 128-bitowego mnożenia wykorzystującego wbudowany montaż PTX. Wymaga PTX 3.0, który jest dostarczany z CUDA 4.2, A kod wymaga GPU z co najmniej zdolnością obliczeniową 2.0, czyli urządzenia klasy Fermi lub Kepler. Kod wykorzystuje minimalną liczbę instrukcje, ponieważ do implementacji mnożenia 128-bitowego potrzebne jest szesnaście 32-bitowych mnożenia. Dla porównania, powyższy wariant przy użyciu CUDA intrinsics kompiluje się do 23 instrukcji dla celu sm_20.

__device__ my_uint128_t mul_uint128 (my_uint128_t a, my_uint128_t b)
{
    my_uint128_t res;
    asm ("{\n\t"
         "mul.lo.u32      %0, %4, %8;    \n\t"
         "mul.hi.u32      %1, %4, %8;    \n\t"
         "mad.lo.cc.u32   %1, %4, %9, %1;\n\t"
         "madc.hi.u32     %2, %4, %9,  0;\n\t"
         "mad.lo.cc.u32   %1, %5, %8, %1;\n\t"
         "madc.hi.cc.u32  %2, %5, %8, %2;\n\t"
         "madc.hi.u32     %3, %4,%10,  0;\n\t"
         "mad.lo.cc.u32   %2, %4,%10, %2;\n\t"
         "madc.hi.u32     %3, %5, %9, %3;\n\t"
         "mad.lo.cc.u32   %2, %5, %9, %2;\n\t"
         "madc.hi.u32     %3, %6, %8, %3;\n\t"
         "mad.lo.cc.u32   %2, %6, %8, %2;\n\t"
         "madc.lo.u32     %3, %4,%11, %3;\n\t"
         "mad.lo.u32      %3, %5,%10, %3;\n\t"
         "mad.lo.u32      %3, %6, %9, %3;\n\t"
         "mad.lo.u32      %3, %7, %8, %3;\n\t"
         "}"
         : "=r"(res.x), "=r"(res.y), "=r"(res.z), "=r"(res.w)
         : "r"(a.x), "r"(a.y), "r"(a.z), "r"(a.w),
           "r"(b.x), "r"(b.y), "r"(b.z), "r"(b.w));
    return res;
}