Włączanie zdalnych połączeń tcpip do już zainstalowanej bazy danych SQL server express za pomocą kodu lub skryptu (zapytanie)

Przetestowałem poniższy kod z SQL Server 2008 R2 Express i uważam, że powinniśmy mieć rozwiązanie dla wszystkich 6 kroków, które opisałeś. Zajmijmy się nimi jeden po drugim:

1-Enable TCP / IP

Możemy włączyć protokół TCP / IP za pomocą WMI :

set wmiComputer = GetObject( _
    "winmgmts:" _
    & "\\.\root\Microsoft\SqlServer\ComputerManagement10")
set tcpProtocols = wmiComputer.ExecQuery( _
    "select * from ServerNetworkProtocol " _
    & "where InstanceName = 'SQLEXPRESS' and ProtocolName = 'Tcp'")

if tcpProtocols.Count = 1 then
    ' set tcpProtocol = tcpProtocols(0)
    ' I wish this worked, but unfortunately 
    ' there's no int-indexed Item property in this type

    ' Doing this instead
    for each tcpProtocol in tcpProtocols
        dim setEnableResult
            setEnableResult = tcpProtocol.SetEnable()
            if setEnableResult <> 0 then 
                Wscript.Echo "Failed!"
            end if
    next
end if

2-Otwórz odpowiednie porty w firewallu

Wierzę, że Twoje rozwiązanie zadziała, po prostu upewnij się, że podałeś odpowiedni port. Proponuję wybrać inny port niż 1433 i zrobić z niego statyczny port SQL Server Express będzie nas słuchał. W tym poście będę używał 3456, ale proszę wybrać inny numer w prawdziwej implementacji (czuję, że wkrótce zobaczymy wiele aplikacji korzystających z 3456 :-)

3-Modify TCP / IP properties enable a IP address

Możemy ponownie użyć WMI. Ponieważ używamy portu statycznego 3456, wystarczy zaktualizować dwie właściwości w sekcji IPAll : wyłączyć porty dynamiczne i ustawić port nasłuchu na 3456:

set wmiComputer = GetObject( _
    "winmgmts:" _
    & "\\.\root\Microsoft\SqlServer\ComputerManagement10")
set tcpProperties = wmiComputer.ExecQuery( _
    "select * from ServerNetworkProtocolProperty " _
    & "where InstanceName='SQLEXPRESS' and " _
    & "ProtocolName='Tcp' and IPAddressName='IPAll'")

for each tcpProperty in tcpProperties
    dim setValueResult, requestedValue

    if tcpProperty.PropertyName = "TcpPort" then
        requestedValue = "3456"
    elseif tcpProperty.PropertyName ="TcpDynamicPorts" then
        requestedValue = ""
    end if

    setValueResult = tcpProperty.SetStringValue(requestedValue)
    if setValueResult = 0 then 
        Wscript.Echo "" & tcpProperty.PropertyName & " set."
    else
        Wscript.Echo "" & tcpProperty.PropertyName & " failed!"
    end if
next

Zauważ, że nie miałem aby włączyć dowolny z poszczególnych adresów, aby to działało, ale jeśli jest to wymagane w Twoim przypadku, powinieneś być w stanie łatwo rozszerzyć ten skrypt, aby to zrobić.

Przypomnę tylko, że podczas pracy z WMI, WBEMTest.exe jest twoim najlepszym przyjacielem!

4-Włącz uwierzytelnianie w trybie mieszanym w sql server

Chciałbym ponownie użyć WMI, ale niestety to ustawienie nie jest narażone przez WMI. Istnieją dwie inne opcje:

1. Use LoginMode property of Microsoft.SqlServer.Management.Smo.Server Klasa, zgodnie z opisem tutaj .

2. Użyj wartości LoginMode w rejestrze SQL Server, jak opisano w ten post . Zauważ, że domyślnie instancja SQL Server Express ma nazwę SQLEXPRESS, więc dla mojej instancji SQL Server 2008 R2 Express właściwy klucz rejestru był HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Microsoft SQL Server\MSSQL10_50.SQLEXPRESS\MSSQLServer.

5-Zmień domyślne hasło użytkownika (sa)

6-Finally (connect to the instance)

Ponieważ używamy portu statycznego przypisany do naszej instancji SQL Server Express, nie ma już potrzeby używania nazwy instancji w adresie serwera.

SQLCMD -U sa -P newPassword -S 192.168.0.120,3456

Proszę dać mi znać, jeśli to działa dla Ciebie (trzymam kciuki!).